Question

I’m using javascript to pad numbers in my xslt file. but when debugging I get an error saying.

Extension function parameters or return values which have Clr type
‘ConcatString’ are not supported.

How can I fix this?

xslt

<xsl:template name="padNumber">
    <xsl:param name="value"></xsl:param>
    <xsl:param name="length"></xsl:param>
    <xsl:value-of select="user:PadDigits($value,$length)"/>
  </xsl:template>

javascript

function PadDigits(n, totalDigits)
{
    n = n.toString();
    var pd = '';
    if (totalDigits > n.length)
    {
        var i;
        for (i=0; i<(totalDigits-n.length); i++)
        {
            pd += '0';
        }
    }
    pd = pd + n.toString();
    return pd;
}

Answer 1

You don’t need an extension function for this at all.

Use this pure XSLT implementation:

 <xsl:template name="padNumber">
    <xsl:param name="pValue"/>
    <xsl:param name="pLength"/>

    <xsl:value-of select=
    "concat(substring(substring($vZeroes,1,$pLength),
                      string-length($pValue) +1),
            $pValue)
    "/>
  </xsl:template>

Here is a complete example:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>

 <xsl:variable name="vZeroes" select=
  "'000000000000000000000000000000000000000'"/>

 <xsl:template match="/">
  <xsl:call-template name="padNumber">
    <xsl:with-param name="pValue" select="12345"/>
    <xsl:with-param name="pLength" select="8"/>
  </xsl:call-template>
 </xsl:template>

 <xsl:template name="padNumber">
    <xsl:param name="pValue"/>
    <xsl:param name="pLength"/>

    <xsl:value-of select=
    "concat(substring(substring($vZeroes,1,$pLength),
                      string-length($pValue) +1),
            $pValue)
    "/>
  </xsl:template>
</xsl:stylesheet>

When this transformation is applied on any XML document (not used in this demo), the wanted, correct result is produced:

00012345

You can further parameterize the wanted padding character to be used:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>

 <xsl:variable name="vZeroes" select=
  "'000000000000000000000000000000000000000'"/>

 <xsl:template match="/">
  <xsl:call-template name="padNumber">
    <xsl:with-param name="pValue" select="12345"/>
    <xsl:with-param name="pLength" select="8"/>
    <xsl:with-param name="pPadChar" select="'*'"/>
  </xsl:call-template>
 </xsl:template>

 <xsl:template name="padNumber">
    <xsl:param name="pValue"/>
    <xsl:param name="pLength"/>
    <xsl:param name="pPadChar" select="'0'"/>

    <xsl:variable name="vZeroes" select="translate($vZeroes, '0', $pPadChar)"/>

    <xsl:value-of select=
    "concat(substring(substring($vZeroes,1,$pLength),
                      string-length($pValue) +1),
            $pValue)
    "/>
  </xsl:template>
</xsl:stylesheet>

When this transformation is performed, the result is now:

***12345