Question

I’m using processing, and I’m curious how to access the properties of a primitive. The reference gives parameters for constructing these primitives, but no info on properties. For example (I’m trying to do something more complicated than this, but this will work for simplicity), if I create a line with a changing length, is there a way to print that line’s length:

int lineLength = 0;

void draw(){
 line(random(0,50),random(0,50),lineLength,lineLength);
 lineLength++;
 printLn(line.length);
}

Answer 1

I’m not sure what you mean by “primitive”. If you mean the drawing functions (e.g. point(),line(),triangle(),rect(),ellipse(),beginShape(),endShape(),vertex(),etc.), then these are simply functions that deal with rendering a shape on screen once with the passed arguments/parameters. After you call the function, the parameters are lost, unless they’re stored in variables somewhere.

For example, a line is defined by two points, so you could store/modify those at will and simply render when needed:

PVector p1,p2;

void setup(){
  p1 = new PVector(random(100),random(100));
  p2 = new PVector(random(100),random(100));
}
void draw(){
  line(p1.x,p1.y,p2.x,p2.y);
  println("length: " + p1.dist(p2));
}

Just because there isn’t a Line class defined in Processing already doesn’t mean you can’t whip out your own version to do exactly what you need it to do:

Line l = new Line(random(100),random(100),random(100),random(100));

void draw(){
  background(127);
  l.draw();
  text("length: " + l.length(),1,10);
  text("mouse dist:\n" + (int)l.distanceToPoint(new PVector(mouseX,mouseY)),1,20);
}

class Line{
  PVector p1,p2;
  Line(float x1,float y1,float x2,float y2){
    p1 = new PVector(x1,y1);
    p2 = new PVector(x2,y2);
  }
  void draw(){
    line(p1.x,p1.y,p2.x,p2.y);
  }
  float length(){
    return p1.dist(p2);
  }
  //other awesome line stuff here
  //'kindly borrowed' from: http://paulbourke.net/geometry/pointline/
  float distanceToPoint(PVector p){
    float dx = p2.x - p1.x;
    float dy = p2.y - p1.y;
    float u = ((p.x - p1.x) * dx + (p.y - p1.y) * dy) / (dx * dx + dy * dy);//traversal(% 0.0 to 1.0) along line
    PVector closest;
    if(u < 0)      closest = p1;
    else if(u > 1) closest = p2;
    else           closest = new PVector(p1.x + u * dx, p1.y + u * dy);
    return closest.dist(p);   
  }
}

You can also use libraries that offer this sort of functionality of course, like toxiclibs for example.

HTH