Question

I’m using Term::ReadLine::Gnu and have run into a problem with signal handling. Given the script below and a TERM signal sent to the script, the handler for the TERM signal is not triggered until after the enter key is pressed. Using Term::ReadLine:Perl this does not occur.

I’ve read that Term::ReadLine::Gnu has its own internal signal handlers, but frankly I’m at a loss as to how to work with them.

I’ve reviewed http://search.cpan.org/~hayashi/Term-ReadLine-Gnu-1.20/Gnu.pm#Term::ReadLine::Gnu_Variables tried setting the rl_catch_signals variable to 0, but that didn’t help. Ideally, I’d like to work with the Gnu signal handlers, but I’ll settle for disabling them too.

To be absolutely specific, I need the TERM handler to trigger after the signal is received instead of waiting for the enter key to be pressed.

Any help or advice is certainly appreciated!

#!/usr/bin/perl

use strict;
use warnings;
use Term::ReadLine;

$SIG{TERM} = sub { print "I got a TERM\n"; exit; };

my $term = Term::ReadLine->new('Term1');
$term->ornaments(0);
my $prompt = 'cmd> ';
while ( defined (my $cmd = $term->readline($prompt)) ) {
    $term->addhistory($cmd) if $cmd !~ /\S||\n/;
    chomp($cmd);
    if ($cmd =~ /^help$/) {
        print "Help Menu\n";
    }
    else {
        print "Nothing\n";
    }
}

Answer 1

This is due to perl’s default paranoid handling of signals – behind the scenes, perl blocks SIGTERM before starting the readline call and restores it when it’s finished. See Deferred Signals in perlipc for the details.

Term::ReadLine::Perl uses perl’s IO, which knows about these issues and deals with them, so you don’t see this bug with it. Term::ReadLine::Gnu uses the C library, which doesn’t, so you do.

You can work around this with one of two methods:

1. set the environment variable PERL_SIGNALS to unsafe before running the script, as in:

   bash$ PERL_SIGNALS=unsafe perl readline-test.pl
   

   Note, BEGIN { $ENV{PERL_SIGNALS} = "unsafe"; } isn’t enough, it needs to be set before perl itself starts.

2. Use POSIX signal functions:

   #~ $SIG{TERM} = sub { print "I got a TERM\n"; exit; };
   use POSIX;
   sigaction SIGTERM, new POSIX::SigAction sub { print "I got a TERM\n"; exit; };
   

   Both the above seem to work in Linux; can’t speak for Windows or other unices. Also, both of the above come with risks – see perlipc for the details.