Question

I’m using the following code inside an ActiveX Script job on SQl Server to call an URL every X minutes.

Dim WshShell
Set WshShell = CreateObject("WScript.Shell")
WshShell.Run "iexplore.exe http://www.google.com.br"
Set WsShell = Nothing

it is working but the processes created keep running:

Any way of changin that code to call the URL and kill the recent called process or call it with a “time-to-live”. I think it is more secure, I wouldn’t want to kill the wrong process.

Answer 1

Following up on the suggestion by @Ted, you can also fetch a URL using native Microsoft capabilities in an in-process fashion. You can do this via a component known as WinHTTP (the latest appears to be WinHTTP 5.1).

See my script below which includes a function to simply obtain the status of a URL. When I run this script I get the following output:

http://www.google.com => 200 [OK]
http://www.google.com/does_not_exist => 404 [Not Found]
http://does_not_exist.google.com => -2147012889
    [The server name or address could not be resolved]

If you want the actual content behind a URL, try oHttp.ResponseText. Here’s the WinHTTP reference if you are interested in other capabilities as well.

Option Explicit

Dim aUrlList
aUrlList = Array( _
    "http://www.google.com", _
    "http://www.google.com/does_not_exist", _
    "http://does_not_exist.google.com" _
)

Dim i
For i = 0 To UBound(aUrlList)
    WScript.Echo aUrlList(i) & " => " & GetUrlStatus(aUrlList(i))
Next

Function GetUrlStatus(sUrl)
    Dim oHttp : Set oHttp = CreateObject("WinHttp.WinHttpRequest.5.1")

    On Error Resume Next

    With oHttp
        .Open "GET", SUrl, False
        .Send
    End With

    If Err Then
        GetUrlStatus = Err.Number & " [" & Err.Description & "]"
    Else
        GetUrlStatus = oHttp.Status & " [" & oHttp.StatusText & "]"
    End If

    Set oHttp = Nothing
End Function