Question

I’m using the following function to add some images from the library to the stage.

function AddImage(image_name:String):void {
    if(image_count == 4) return;
    // change the following line so it uses "image_name"
    var defaultImage:added_1 = new added_1(100, 100);
    var tmpImage:Bitmap = new Bitmap(defaultImage);
    tmpImage.x = 124.5 + (108.5 * image_count);
    tmpImage.y = 1511.9;
    addChild(tmpImage);
    image_count++;
}

What I’d like to be able to do is pass the image name as a string parameter to the function but can’t seem to figure out how to do this.

Can someone help me out?

Answer 1

What you want to do is get the Class Definition via using getDefinitionByName so that you can create an instance, the following code is how you do that :

// you'll need to add this import to use getDefinitionByName
import flash.utils.getDefinitionByName;

function AddImage(image_name:String):void {
    if(image_count == 4) return;
    // this next line gets the class definition of the image_name
    var imageClass:Class = getDefinitionByName(image_name) as Class;
    // this is how you create an instance of that class
    var defaultImage:BitmapData = new imageClass(100, 100);
    var tmpImage:Bitmap = new Bitmap(defaultImage);
    tmpImage.x = 124.5 + (108.5 * image_count);
    tmpImage.y = 1511.9;
    addChild(tmpImage);
    image_count++;
}

The changes are the import :

import flash.utils.getDefinitionByName;

and these two lines :

 var imageClass:Class = getDefinitionByName(image_name) as Class;
 var defaultImage:BitmapData = new imageClass(100, 100);

Note —
Also wanted to mention that in certain cases you might run into an issue if you are compiling with Flex as opposed to the Flash IDE, where you get the following error :

ReferenceError: Error #1065: Variable <YourImageClassName> is not defined.

The way to handle that situations is by declaring a variable in your class variable declarations for the compiler, so it recognizes that symbol.

So if your two images class names were image_1 and image_2, in your class declarations you would do something like :

private var forCompiler1:image_1;
private var forCompiler2:image_2;

If you have a ton of images, that might be a pain, but that’s the only way I’ve found to get the compiler to recognize them. :/ haha