Question

I’m using the Muenchian method to group nodes in an XML document.

As part of my output, I’d like to select all of the nodes to which I have not assigned a key.

I’ve tried

<xsl:apply-templates select="*[key('kcWWPN','')]"/>

but that doesn’t appear to be working correctly, in that it is selecting no nodes.

Any suggestions on the right way to do this?

Answer 1

As part of my output, I’d like to select all of the nodes to which I
have not assigned a key.

Good question, +1.

Here are two different, but simple solutions:

For simplicity I will assume that we are keying only elements, but the two solutions below can naturally be extended to cover other types of nodes.

I. Simply, define a counter-key:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:key name="kDByClass" match="d" use="@class"/>

 <xsl:key name="kCounterKey" match="*[not(self::d)]" use="."/>

 <xsl:template match="*[key('kCounterKey', .)]">
  Counter Keyed: <xsl:value-of select="name()"/>

  <xsl:apply-templates/>
 </xsl:template>

 <xsl:template match="text()"/>
</xsl:stylesheet>

when this transformation is applied on the following XML document (borrowed from @lwburk):

<root>
    <d class="test">1</d>
    <d class="test">2</d>
    <d class="something">1</d>
    <q>3</q>
</root>

the wanted, correct result is produced:

  Counter Keyed: root
  Counter Keyed: q

II. Use the set difference of all elements and all keyed elements (the latter is found using Muenchian grouping):

This solution is simpler than the first, because one doesn’t need to compose a counter-key:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:key name="kDByClass" match="d" use="@class"/>

 <xsl:key name="kCounterKey" match="*[not(self::d)]" use="."/>

 <xsl:variable name="vKeyedValues" select=
 "//*[generate-id()
     = generate-id(key('kDByClass', @class)[1])
     ]
      /@class
  "/>

  <xsl:variable name="vKeyedElements" select=
   "key('kDByClass', $vKeyedValues)"/>

  <xsl:variable name="vNonKeyedElements" select=
  "//*[not(count(.|$vKeyedElements) = count($vKeyedElements))]
  "/>

 <xsl:template match="/">
  <xsl:for-each select="$vNonKeyedElements">
    Not Keyed: <xsl:value-of select="name()"/>
  </xsl:for-each>
 </xsl:template>

 <xsl:template match="text()"/>
</xsl:stylesheet>

when this transformation is applied on the same XML document (above), again the same, correct result is produced:

Not Keyed: root
Not Keyed: q

Note: The last solution may not work when the key is not a node, but result of a function, such as substring-before(). In this case we simply modify the original key, so thet its use attribute is simply: use="." and use this solution with the modified original key. It can be prooven that this procedure produces the correct, wanted set of elements.