Question

I’m working on a dispatching script. It takes a string with a command, does some cooking to it, and then parses it. But I can’t grab a hold into the referencing:

Use::strict;
Use:warnings;

my($contexto, $cmd, $target, $ultpos, @params);
my $do = "echo5 sample string that says stuff ";

$target = "";
$cmd = "";
$_ = "";
# I do some cumbersome string parsing to get the array with
# the exploded string and then call parsear(@command)

sub parsear {

   my %operations = (
       'echo'   => \&echo,
       'status' => \&status,
       'echo5'  => \&echo5,
   );

   my $op = $_[0];
   if ($operations{$op}){
       $operations{$op}->(@_);
       print "it exists\n";
   }
   else{
       print "incorrect command.\n";
   }
}


sub status {
    print "correct status.\n";
}

sub echo {
    shift(@_);
    print join(' ',@_) . "\n";
}

sub echo5 {
    shift(@_);
    print join(' ',@_) . "\n" x 5;
}

I don’t really know what the problem is. If the sub does not exist, it never says "incorrect command", and if I call for example "echo5 hello" it should print out:

hello
hello
hello
hello
hello

But it does nothing.

And when I call echo, it works as expected. What is the explanation?

Note: I’m on the latest version of Strawberry Perl

Answer 1

use strict;  # 'use' is a keyword
use warnings;

# All these variables are not needed

sub parsear {  # Learn to indent correctly
    my %operations = (
        'echo'   => \&echo,
        'status' => \&status,
        'echo5'  => \&echo5,
    );
    my $op = shift;  # take first element off @_
    if ($operations{$op}) {
        print "$op exists\n";  # Make your status message useful
        $operations{$op}->(@_);
    } else {
        print "incorrect command: $op\n";  # And your error message
    }
}

sub status {
    print "correct status.\n";
}

sub echo {
    # shift(@_); # This is no longer needed, and now echo can be used as a
                 # normal subroutine as well as a dispatch target
    print join(' ',@_) . "\n";
}

sub echo5 {
    # shift(@_); # This is no longer needed
    print +(join(' ',@_) . "\n") x 5;  # Parentheses are needed since x binds tightly
}

Then running:

parsear 'status';
parsear 'echo', 'hello';
parsear 'echo5', 'hello';
parsear 'an error';

results in:

status exists
correct status.
echo exists
hello
echo5 exists
hello
hello
hello
hello
hello
incorrect command: an error

I am not sure what "cumbersome string parsing" you are doing since you did not include it, but if you are parsing a string like

my $do = "echo5 sample string that says stuff ";

where the command is the first word, and the arguments are the rest, you can either split everything:

parsear split /\s+/, $do;

Or use a regex to cut the first word off:

my ($cmd, $arg) = $do =~ /^(\w+)\s*(.*)/;

parsear $cmd => $arg;

You don’t even need the variables:

parsear $do =~ /^(\w+)\s*(.*)/;

---

Finally, the echo5 subroutine is a bit more complicated than it needs to be. It could be written as:

sub echo5 {
    print "@_\n" x 5;  # "@_" means join($", @_) and $" defaults to ' '
}