Question

I’m working on a home work assignment. The question is:

Write an awk script to select all regular files (not directories or
links) in /etc ending with .conf, sort the result by size from
smallest to largest, count the number of files, and print out the
number of files followed by the filenames and sizes in two columns.
Include a header row for the filenames and sizes. Paste both your
script and its output in the answer area.

I’m really struggling trying to get this to work through using awk. Here’s what I came up with.

 ls -lrS /etc/*.conf |wc –l 

will return the number 33 which is the number of files .conf files in the directory.

 ls -lrS /etc/*.conf |awk '{print "File_Size"": " $5 "   ""File_Name and Size"": " $9}'

this will make 2 columns with the name and size of the .conf file in the directory.

It works, but I don’t think it is what he’s looking for. I’m having an AWKful time.

Answer 1

Let’s see here…

select all regular files (not directories or links)

So far you haven’t addressed this, but if you are piping in the output of ls -l..., this is easy, select on

/^-/

because directories start with d, symbolic links with l and so on. Only plain old files start with -. Now

print out the number of files followed

Well, counting matches is easy enough…

BEGIN{count=0}  # This is not *necessary*, but I tend to put it in for clarity
/^-/ {count++;}

To get the filename and size, look at the output of ls -l and count up columns

BEGIN{count=0}
/^-/ {
  count++;
  SIZE=$5;
  FNAME=$9;
}

The big difficulty here is that awk doesn’t provide much by way of sorting primitives, so that’s the hard part. That can be beaten if you want to be clever but it is not particularly efficient (see the awful thing I did in a [code-golf] solution). The easy (and unixy) thing to do would be to pipe part of the output to sort, so…we collect a line for each file into a big string

BEGIN{count=0}
/^-/ {
  count++
  SIZE=$5;
  FNAME=$9;
  OUTPUT=sprintf("%10d\t%s\n%s",SIZE,FNAME,OUTPUT);
}
END{
   printf("%d files\n",count);
   printf("  SIZE    \tFILENAME"); # No newline here because OUTPUT has it
   print OUTPUT|"sort -n --key=1";
}

Gives output like

11 files
  SIZE          FILENAME
       673      makefile
      2192      houghdata.cc
      2749      houghdata.hh
      6236      testhough.cc
      8751      fasthough.hh
     11886      fasthough.cc
     19270      HoughData.png
     60036      houghdata.o
    104680      testhough
    150292      testhough.o
    168588      fasthough.o

(BTW–There is a test subdirectory here, and you’ll note that it does not appear in the output.)