Question

I’m working with a third-party library interfacing to an old database system. There’s a method – CallProg that calls a “stored procedure” (for lack of a better translation – any Pick users in the crowd?). However, instead of doing something like this:

Public Sub CallProg(ProgName, ParamArray ProgArgs() As String)
    ...
End Sub

or even this:

Public Sub CallProg(ProgName, Optional Arg1 As String, Optional Arg2 As String ... Optional Arg20 As String)

They did this:

Public Sub CallProg(ProgName)
Public Sub CallProg(ProgName, Arg1 As String)
Public Sub CallProg(ProgName, Arg1 As String, Arg2 As String)
Public Sub CallProg(ProgName, Arg1 As String, Arg2 As String, Arg3 As String)
...
Public Sub CallProg(ProgName, Arg1 As String, ... Arg20 As String)

I’m writing an abstraction class to handle logging in, setting the environment, etc., so it can be used as a generic “helper” class in a number of other projects. Is there any way to wrap the CallProg sub that doesn’t involve 20 overloads?

Answer 1

This is a very quick idea of how to do it using reflection. I’m not sure if its the best way but it should work…

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load

    CallProg("ProgName", {"testArg1", "TestArg2"})

End Sub

Private Sub CallProg(ByVal ProgName As String, ByVal Params As IEnumerable(Of String))

    Dim testClass As New Test1

    Dim methodTypes As List(Of Type) =
        Params.Select(Function(x) GetType(String)).ToList

    methodTypes.Add(GetType(String))

    Dim methodToBeCalled As Reflection.MethodInfo =
        testClass.GetType.GetMethod("CallProg",
                                    System.Reflection.BindingFlags.Instance Or System.Reflection.BindingFlags.Public,
                                    Type.DefaultBinder,
                                    methodTypes.ToArray,
                                    Nothing)


    Dim paramsToPass As New List(Of String)

    paramsToPass.Add(ProgName)
    paramsToPass.AddRange(Params)

    methodToBeCalled.Invoke(testClass, paramsToPass.ToArray)

End Sub

End Class

Public Class Test1

Public Sub CallProg(ByVal ProgName As String)
    Debug.WriteLine("Sub0 called")
End Sub

Public Sub CallProg(ByVal ProgName As String, ByVal Arg1 As String)
    Debug.WriteLine("Sub1 called")
End Sub

Public Sub CallProg(ByVal ProgName As String, ByVal Arg1 As String, ByVal Arg2 As String)
    Debug.WriteLine("Sub2 called")
End Sub

Public Sub CallProg(ByVal ProgName As String, ByVal Arg1 As String, ByVal Arg2 As String, ByVal Arg3 As String)
    Debug.WriteLine("Sub3 called")
End Sub

End Class