Question

I’m working with Embarcadero Delphi XE2 and Firebird DB, using TIBDatabase, TIBTransaction and TIBTable components. In a form user can edit data of a DB table and commit/rollback the changes when he wants. When he closes the form I’d like to ask him if he wants to commit/rollback pending changes.

But only if there are pending changes. Otherwise I don’t want to bother/confuse the user. How can I determine it? I tried Active and InTransaction transaction’s properties, but they are always true. If it can be usefull, note that I set AllowAutoStart to true on the transaction. Thanks!

Answer 1

You could keep track of the pending updates yourself: turn the flag on in your table’s AfterDelete and AfterPost events; turn it off in AfterTransactionEnd:

// IBTable1.AfterDelete
procedure TForm1.IBTable1AfterDelete(DataSet: TDataSet);
begin
  FPendingUpdates := True;
end;

// IBTable1.AfterPost
procedure TForm1.IBTable1AfterPost(DataSet: TDataSet);
begin
  FPendingUpdates := True;
end;

// IBTable1.AfterTransactionEnd
procedure TForm1.IBTable1AfterTransactionEnd(Sender: TObject);
begin
  FPendingUpdates := False;
end;

// Form1.OnCloseQuery
procedure TForm1.FormCloseQuery(Sender: TObject; var CanClose: Boolean);
var
  DlgResult: TModalResult;
begin
  CanClose := False;

  if FPendingUpdates then
    DlgResult := MessageDlg('Commit pending updates before closing?', mtConfirmation,
      [mbYes, mbNo, mbCancel], 0, mbCancel)
  else
    DlgResult := mrNo;

  case DlgResult of
    mrYes:
      IBTransaction1.Commit;
    mrNo:
      IBTransaction1.Rollback;
    mrCancel:
      Exit;
  end;

  CanClose := True;
end;