Question

I’m writing a code to find the file which not contain a string pattern. Provided I have a list of files, I have to look into the content of each file, I would like to get the file name if the string pattern “clean” not appear inside the file. Pls help.

Here is the scenario:
I have a list of files, inside each file is having numerous of lines. If the file is clean, it will have the “clean” wording. But if the file is dirty, the “clean” wording not exist and there will be no clear indication to tell the file is dirty. So as long as inside each file, if the “clean” wording is not detect, I’ll category it as dirty file and I would like to trace the file name

Answer 1

If you need to generate the list within Perl, the File::Finder module will make life easy.

Untested, but should work:

use File::Finder;

my @wanted = File::Finder              # finds all         ..
              ->type( 'f' )            # .. files          ..
              ->name( '*.txt' )        # .. ending in .txt ..
              ->in( '.' )              # .. in current dir ..
              ->not                    # .. that do not    ..
              ->contains( qr/clean/ ); # .. contain "clean"

print $_, "\n" for @wanted;

Neat stuff!

EDIT:

Now that I have a clearer picture of the problem, I don’t think any module is necessary here:

use strict;
use warnings;

my @files = glob '*.txt';  # Dirty & clean laundry

my @dirty;

foreach my $file ( @files ) {     # For each file ...

    local $/ = undef;             # Slurps the file in
    open my $fh, $file or die $!;

    unless ( <$fh> =~ /clean/ ) { # if the file isn't clean ..
        push @dirty, $file;       # .. it's dirty
    }

    close $fh;
}

print $_, "\n" for @dirty;        # Dirty laundry list

---

Once you get the mechanics, this can be simplified a la grep, etc.