Question

In a VB macro for Excel, how do I remove all occurances of a word that starts with a certain string?

Eg:

The string reads: xxxx $AUD543.43 yyyy

I want to search for anything in a string that starts with $AUD and remove the whole word before the next space

So the example above should result in:

xxxx yyyy

Answer 1

It would be remiss of me not to remind you of the expectation that you show “what you (have) tried”. (Which I do to avoid me being yelled at for answering the question.) My duty thus having been done, I now move on to it.

You actually don’t necessarily need VBA code to do this; you could do it with the Find() function albeit more clumsily and I wouldn’t recommend it for a really large sheet. Still, VBA code you have specified, and that you shall have. Change the range to match the one that you’ll be searching. ALSO, you should note that you have only one space between the x’s and y’s in your example but that varies from your request that it be the word starting with $AUD and ending BEFORE the next space. If you want only one space, please adjust the formulas accordingly.

Sub ReplaceText()

Dim rng As Excel.Range
Dim s_Contents As String
Dim l_FindAUD As Long, l_FindSpace As Long

For Each rng In ActiveSheet.UsedRange

    s_Contents = rng.Value

    'Does the $AUD expression exist in this cell?
    l_FindAUD = InStr(1, s_Contents, "$AUD", vbTextCompare)

    If l_FindAUD > 0 Then

        'If so, is it followed by a space?
        l_FindSpace = InStr(l_FindAUD, s_Contents, " ")

        If l_FindSpace > 0 Then

            'If so, take all of the content up to but not including the $
            'and all of the contents from the space onwards, merge them
            'together and write to the cell.
            s_Contents = Left$(s_Contents, l_FindAUD - 1) & Mid$(s_Contents, l_FindSpace)
            rng.Value = s_Contents
        End If

    End If

Next


End Sub