Question

In HTML there are tags for underlining and making bold, <u> and <b> respectively. Suppose I create a tag which does either of these or both, then how to interpret it using XSLT..?

For example –

<Line type="B">stackoverflow</Line>
<Line type="U">stackoverflow</Line>
<Line type="BU">stackoverflow</Line>

The HTML output should be like this –

<b>stackoverflow</b>
<u>stackoverflow</u>
<b><u>stackoverflow</b></u>

I guess this functionality will only be with XSLT part.

Answer 1

One way to do this is with a recursive template, which recursively checks each letter of the type attribute of the line. So, to create the first element you would do the following (where $type is the variable containing the attribute value):

<xsl:element name="{substring($type, 1, 1)}">

Then you would recursively call the named template with the remaining part of the attribute value

<xsl:call-template name="Line">
   <xsl:with-param name="type" select="substring($type, 2)"/>
</xsl:call-template>

So, given the following XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:template match="@*|node()">
      <xsl:copy>
         <xsl:apply-templates select="@*|node()"/>
      </xsl:copy>
   </xsl:template>

   <xsl:template match="Line" name="Line">
      <xsl:param name="type" select="@type"/>
      <xsl:choose>
         <xsl:when test="not($type)">
            <xsl:value-of select="."/>
         </xsl:when>
         <xsl:otherwise>
            <xsl:element name="{substring($type, 1, 1)}">
               <xsl:call-template name="Line">
                  <xsl:with-param name="type" select="substring($type, 2)"/>
               </xsl:call-template>
            </xsl:element>
         </xsl:otherwise>
      </xsl:choose>
   </xsl:template>
</xsl:stylesheet>

When applied to the following XML

<Lines>
   <Line type="B">stackoverflow</Line> 
   <Line type="U">stackoverflow</Line> 
   <Line type="BU">stackoverflow</Line>
   <Line>No format</Line>
</Lines>

Will output the following

<Lines>
   <B>stackoverflow</B>
   <U>stackoverflow</U>
   <B><U>stackoverflow</U></B>
   No format
</Lines>

Note, to stop the Lines element being output in this case, just add the following template to the XSLT:

<xsl:template match="Lines">
   <xsl:apply-templates select="@*|node()"/>
</xsl:template>