Question

In my perl script Ive filled a two dimensional hash by collecting CDP neighbour information from cisco routers in my network via SNMP (in this case ip addresses of the devices). Hashes have allowed me to limit duplicates and capture parent daughter relationships.

$name{$hostIP}{$neighbourIP} = $name;

I’d like to use the hashed data with D3.js (in a dendrogram) to illustrate the router topology or connection relationships and need the data formatted in JSON recursively like:

{
 name: "10.120.5.1",
 children: [
  {
   name: "10.120.5.2",
   children: [
    {
     name: "10.120.5.3",
     children: [
      {
       name: "10.120.5.4"
      },
      {
       name: "10.120.6.1"
      },
      {
       name: "10.120.6.2"
      },
      {
       name: "10.120.6.3"
      }
     ]
    }
   ]
  }
 ]
}

Can someone provide examples using libraries or normal print statements showing how to convert the hash format to JSON similar to the above? Perl is preferred but any language like python, C would help. Also if anyone knows of any open source scripting that does this job already I’d love to compare.

Answer 1

Does this help with the recursion? Starting from a hash similar to yours, I perform

• a breadth-first search to see which children can be listed with which parents
• followed by a depth-first walkthrough of that intermediary structure, to build a hash equivalent to your json sample
• followed by a straight dump to json.

Walking the data twice seems sub-optimal, but not doing it results in very deep dendrograms.

#!/bin/perl

use 5.010; # Enable 'say'. Sorry, old perl
use strict;
use warnings;
use JSON::PP; # Just 'use JSON;' on most systems

# 0. set up some data in adjacency table
my %name;
$name{'10.120.5.1'}{'10.120.5.2'}++;
$name{'10.120.5.2'}{'10.120.5.1'}++;

$name{'10.120.5.2'}{'10.120.5.3'}++;
$name{'10.120.5.3'}{'10.120.5.2'}++;

$name{'10.120.5.3'}{'10.120.5.4'}++;
$name{'10.120.5.4'}{'10.120.5.3'}++;

$name{'10.120.5.3'}{'10.120.6.1'}++;
$name{'10.120.6.1'}{'10.120.5.3'}++;

$name{'10.120.5.3'}{'10.120.6.2'}++;
$name{'10.120.6.2'}{'10.120.5.3'}++;

$name{'10.120.5.3'}{'10.120.6.3'}++;
$name{'10.120.6.3'}{'10.120.5.3'}++;


# 1. set up helper structures
# pick a starting point
(my $root) = keys %name;

# empty structures
my %nodes = ();
my %tree  = ();
my @queue = ($root);

# 2. First pass: BFS to determine child nodes 
list_children(\%name, \@queue, \%nodes) while @queue;

# 3. Second pass: DFS to set up tree
my $tree = build_tree($root, \%nodes);

# 4. And use JSON to dump that data structure
my $json = JSON::PP->new->pretty; # prettify for human consumption

say $json->encode($tree);

sub list_children {
  my $adjac = shift;
  my $queue  = shift;
  my $nodes  = shift;

  my $node = shift @$queue;

  # all child nodes
  my @children = keys %{$adjac->{$node}};

  # except the ones we visited earlier, to avoid loops
  @children = grep { ! exists $nodes->{$_}} @children;

  $nodes->{$node} = \@children;

  # and toss on the queue
  push @$queue, @children;
}

sub build_tree {
  my $root  = shift;
  my $nodes = shift;

  my @children;
  for my $child (@{$nodes->{$root}}) {
    push @children, build_tree($child, $nodes);
  }

  my %h = ('name'     => $root,
           'children' => \@children);

  return \%h;
}