Question

In perl DBI, you can bind a hash element value to a specific column of your query results.
Such that,
as you fetch each row, the hash element value is updated to the current row.

I’m trying to figure out if there’s a way to accomplish that in core perl,
using an hash of (array of arrays).

The end goal is to be able to run something like this:

my $i;
my @a = (
  [1,2,3],
  [4,5,6],
  [7,8,9]
);
my %superhash{'first', 'second', 'third'} = (\$i[0], \$i[1], \$i[2]);
for $i (@a) {
  print ${$hash{'first'}} . "\n";
}

I’d love to be able to point $hash{'first'} to the first element in an arrayref, without having to have an array to point to beforehand.

Expected output:

1
4
7

Of course, that code doesn’t work, because there are no elements that $i references to, thus they are undefined.

Answer 1

The tie interface is Perl’s way of making magic variables. In this case, a bit of glob magic needs to be thrown in due to the way the for loop assigns to its loop variable.

my @a = (
    [1,2,3],
    [4,5,6],
    [7,8,9]
);

{package Tie::Rows;
    my %keys = qw(first 0 second 1 third 2);
    sub TIEHASH {bless [$_[1]]}               # store glob reference
    sub FETCH {$${$_[0][0]}[$keys{$_[1]}]}    # deref glob as array, lookup key
}

tie my %hash, 'Tie::Rows', *i;  # passing the glob here

for our $i (@a) {  # since the for loop aliases at that level
    print $hash{first} . "\n";
}

which prints

1
4
7

---

You can also exploit dynamic scope to solve this problem:

sub first  () {$$_[0]}  # each of these uses the array in $_
sub second () {$$_[1]}
sub third  () {$$_[2]}

for (@a) {              # for loop puts each array into $_
    print second, $/;
}

which prints

2
5
8