Question

In VBA is it possible to intercept a javascript onchange event and grab the originating ID# in the webbrowser control?

<select name="status0" id="status0" onchange="javascriptonchangeeventhere">

The above code is a combobox demo, If I were to select an item from the combobox, it would process onchange in javascript. What it does is pull up a form containing current date and reference number, instead I would like to pull up my own userform and then spit that data into a related (notes0) field. How would I intercept this when it occurs so I can assign it to the correct field.

Answer 1

Here’s a short example. Project references set for “Microsoft HTML object library” and “Microsoft internet controls”

In a class module “clsEvents”:

Option Explicit

Public WithEvents slct As MSHTML.HTMLSelectElement
Public WithEvents href As MSHTML.HTMLAnchorElement

'Note that having defined "href" as "WithEvents", if you choose "href"
'  from the left-hand dropdown at the top of the class code module
'  then the right-hand dropdown will populate with events you can select
'  from to create an event-handling procedure in the class

Private Function href_onclick() As Boolean
    Debug.Print "link clicked"
    href_onclick = False 'cancels the navigation
End Function

Private Sub slct_onchange()
    Debug.Print "select onchange - value is " & slct.Value
End Sub

Private Function slct_onclick() As Boolean
    Debug.Print "select onclick - value is " & slct.Value
End Function

In a regular module:

Option Explicit

Dim evt As clsEvents

Sub Setup()

    Dim IE As New InternetExplorer
    Dim el As Object, el2 As Object

    Set evt = New clsEvents

    IE.Visible = True
    IE.navigate "http://www.csee.wvu.edu/~riggs/html/select_example.html"

    Do While IE.Busy
    Loop

    Set el = IE.document.getElementsByTagName("select")(1)
    Set el2 = IE.document.getElementsByTagName("a")(1)

    If Not el Is Nothing Then
        Debug.Print "setting event capture: currentvalue=" & el.Value
        Set evt.slct = el
    End If

    If Not el2 Is Nothing Then
        Debug.Print "setting event capture on link:" & el2.innerText
        Set evt.href = el2
    End If

End Sub

If you run the Setup sub and then change the value of the second select or click the “Javascript” link on the page in IE you should see output in the Immediate window of the VB editor.

Hope that helps get you started.