Question

Is it possible change the type (or copy) a double type array into a char?

My objective is mix accurate data with strings, and then write to .txt file.

---

With your tips, I reach this code:

Program logArray

Implicit None

Integer, Parameter :: wp = Selected_real_kind( 12, 70 )

Real( wp ), Dimension( 1:5 ) :: vals
Character( Len = 40 ), Dimension( 1:5 ) :: stuff

character (40) :: fileName
Integer :: i,stat


Call Random_number( vals )

write(*,*) 'Printing Values from Real array'
do i = 1, 5
    write(*,*) 'vals', i, vals(i)
end do


Write( stuff, '( "Value ", i1, " is ", f20.16 )' ) &
   ( i, vals( i ), i = 1, Size( vals ) )

fileName='log.txt'

open(2, file=fileName, status='replace', iostat=stat)
    if (stat /= 0) then
        write(*,*) fileName, ' The file  cannot be opened !'
        go to 20
    end if

    !Write( *, '( 99999( a, :, / ) )' ) stuff  
    Write( 2, '( 99999( a, :, / ) )' ) stuff 

    close(2)


    20 write(*,*) 'File Closed' 

End Program logArray

However, I still don’t get it, if I want to write on log.txt something like

“—–Title of Value 1———“

Value 1 is 0.9975595900926172
Value 2 is 0.5668247076112733

“—–Value 3 means love——-“
Value 3 is 0.9659153754961249
Value 4 is 0.7479276854714322
Value 5 is 0.3673908973747557

I’m newbie at Fortran. I used to write to files with cycles, your “magic” instruction does the things in a different way, and I don’t get it how can I manipulate in main favor.

Thank you very much for your help

Answer 1

Not quite sure what you mean, but what you probably need is an internal file – this is how you convert numeric data to/from character form in Fortran. Here’s an example:

[luser@cromer stackoverflow]$ cat char.f90
Program char

  Implicit None

  Integer, Parameter :: wp = Selected_real_kind( 12, 70 ) 

  Real( wp ), Dimension( 1:5 ) :: vals

  Character( Len = 40 ), Dimension( 1:5 ) :: stuff

  Integer :: i

  Call Random_number( vals )

  Write( stuff, '( "Value ", i1, " is ", f20.16 )' ) &
       ( i, vals( i ), i = 1, Size( vals ) )

  Write( *, '( 99999( a, :, / ) )' ) stuff

End Program char
[luser@cromer stackoverflow]$ nagfor -C=all -C=undefined char.f90
NAG Fortran Compiler Release 5.3.1 pre-release(904)
[NAG Fortran Compiler normal termination]
[luser@cromer stackoverflow]$ ./a.out
Value 1 is   0.5247509555250293         
Value 2 is   0.2338414404620047         
Value 3 is   0.8165253430643411         
Value 4 is   0.2788076219798084         
Value 5 is   0.9609032005446272         

The line

  Write( stuff, '( "Value ", i1, " is ", f20.16 )' ) &
       ( i, vals( i ), i = 1, Size( vals ) )

is the one that does the magic – It writes out vals according to the format given, but instead of writing to file it writes to the character array stuff, each element of the array acting as a record i the “file”

I hope this makes sense. To be more specific we need more details.