Question

Is it possible in a VBA function (UDF) to create an object that has global scope? I.e persists beyond the runtime of the function? I would want to stick it in a hash with a unique key that I can pass to other functions. I know you can do this in c#/c++ dll’s.

The motivation is a heavy duty piece of processing that I don’t want to repeat across hundreds of function calls: I want to cache the results so I only need to do once. E.g let’s imagine I have a UDF which builds the results object in Cell A1:

=CreateResultsObject(arg1, arg2, arg3...)

The function does the heavy work and returns a unique ID string (the key for the object stored in the persistent hash). Cell A1 now contains this string value which I can then pass to other functions: they can then access the cached object in the hash with the key.

Is this possible? If so how?

Answer 1

The variables you declare in a module are persistent.

This code in a module might go into the direction you want:

Option Explicit

Dim col As New Collection


Public Function GetValue(ByVal strName As String) As String

    GetValue = col.Item(strName)

End Function

Public Sub SetValue(ByVal strName As String, ByVal strValue As String)

    col.Add strValue, strName

End Sub

Note:

For duplicate or missing names the code will fail.
Instead of a string value any kind of object could be passed by modifying the function signatures accordingly.

Addendum:

The same code with a bit more intelligence – for existing keys in the collection the value will be replaced instead of failing with an error.

Option Explicit

Dim col As New Collection


Public Function GetValue(ByVal strName As String) As String

    GetValue = col.Item(strName)

End Function

Public Sub SetValue(ByVal strName As String, ByVal strValue As String)

    If HasValue(strName) Then
        col.Remove (strName)
    End If

    col.Add strValue, strName

End Sub

Private Function HasValue(ByVal strName As String) As Boolean

    Dim val As Variant
    Dim bRes As Boolean

    bRes = True

On Error Resume Next

    val = col.Item(strName)

    If Err.Number <> 0 Then
        bRes = False
        Err.Clear
    End If
On Error GoTo 0

    HasValue = bRes

End Function