Question

Is it possible in Perl to access a value of a hash, if it has just one key, without using key value?

Let’s say, %h has just 'key_name' => 'value'.

Can I access the 'value' only via $h->{key_name}?

Or, is possible to access this 'value' without key name?

Answer 1

The values builtin function for hashes will return a list of all the hash values. You can use this to get or set any values with aliasing list constructs such as foreach, map, and grep:

for my $value (values %hash) {
    say $value;  # prints the value
    $value++;    # adds one to the value
}

Or you can store the values in an array:

my @vals = values %hash;

The order of the returned values is effectively random, but it will be the same order as the corresponding keys function.

Hashes themselves are lists, so you can access any odd element of the hash in list context to get at the value, but this method is less efficient since the whole hash needs to be taken apart to form the list, not just the values.

The techniques above work with hashes of any size. If you only have one key / value pair:

my %hash = qw(foo bar);

Then they reduce to:

{my ($x) = values %hash;    say $x} # bar
{my (undef, $x) = %hash;    say $x} # bar
{my $x = (values %hash)[0]; say $x} # bar
{my $x = (%hash)[1];        say $x} # bar