Question

Is it possible to control cpu usage using Perl script in an idle machine?

like some.pl 50 will consume 50% cpu, some.pl 100 will consume 100% cpu usage.

Answer 1

Yes, certainly it is possible. The following snippet calculates the percentage of processor load for a certain process in an instant of time. You probably first want to collect a certain number of values and average them for a smooth result.

Then simply, if the load is not high enough, tell the process to do work, if the load is too high, tell the process to pause work.

use constant UTIME => 13;
use constant STIME => 14;
use List::Util qw(sum);
use Time::HiRes qw(sleep);
use autodie qw(:all);

sub pidload {
    my ($pid) = @_;
    open my $pstat, '<', "/proc/$pid/stat";
    my @pstat = split ' ', <$pstat>;
    close $pstat;
    return $pstat[UTIME] + $pstat[STIME];
}

sub cpuload {
    open my $stat, '<', '/proc/stat';
    my @total = split ' ', <$stat>;
    close $stat;
    shift @total;
    return sum @total;
}

my ($pid) = @ARGV;
my $prev_cpu = cpuload;
my $prev_pid = pidload $pid;
while (1) {
    sleep 0.1;
    my $now_pid = pidload $pid;
    my $now_cpu = cpuload;
    printf "%.0f\n", 100*(($now_pid - $prev_pid) / ($now_cpu - $prev_cpu));
    $prev_cpu = $now_cpu;
    $prev_pid = $now_pid;
}