Question

Is it possible to define a user-defined type constant at module level?

Type MyType
    name as String
    description as String
End Type

' Something like this
Private Const OneType as MyType = "Name" "Description" 

Answer 1

No. Const does not work with user-defined-types. The closest you can come is to create a class that only has property gets.

Public Property Get Name() As String
   Name = "Name"
End Property

Public Property Get Description() As String
   Description = "Description"
End Property

If you want to have multiple instances of the class with different values but still want the values to be constant, then add an initialize routine that can only be used once.

Private sName As String
Private sDescription As String

Private Sub Class_Initialize()
   sName = ""
End Sub

Public Sub Initialize(Name As String, Description As String)
   If Len(sName) = 0 Then
      sName = Name
      sDescription = Description
   Else
      MsgBox "This instance of MyClass is already initialized!"
   End If
End Sub

Public Property Get Name() As String
   Name = sName
End Property
Public Property Get Description() As String
   Description = sDescription
End Property

then declare an instance of your class.

Dim cMyClass1 As New MyClass, cMyClass2 as New MyClass
cMyClass1.Initialize("Name","Description")
cMyClass2.Initialize("DiffName","OtherDescription")