Question

Is it possible to have a for-each in which the counter is an attribute value (not a node list)?
Here is what I am trying to do, handling colspan in tables (doesn’t work):

        <xsl:for-each select=".//tr[1]//td">
            <xsl:choose>
                <xsl:when test="@colspan">
                    <xsl:for-each select="@colspan">
                        <fo:table-column/>
                    </xsl:for-each>
                </xsl:when>
                <xsl:otherwise><fo:table-column/></xsl:otherwise>
            </xsl:choose>
        </xsl:for-each>

Thanks!

Answer 1

In XSLT 2.0:

<xsl:for-each select="1 to xs:integer(@colspan)">
 <fo:table-column/>
</xsl:for-each>

In XSLT 1.0:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:fo="http://www.w3.org/1999/XSL/Format">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="table[@colspan]">
    <fo:table>
      <xsl:call-template name="generate"/>
    </fo:table>
 </xsl:template>

 <xsl:template name="generate">
  <xsl:param name="pTimes" select="@colspan"/>

  <xsl:if test="$pTimes > 0">
   <fo:table-column/>

   <xsl:call-template name="generate">
     <xsl:with-param name="pTimes" select="$pTimes -1"/>
   </xsl:call-template>
  </xsl:if>
 </xsl:template>
</xsl:stylesheet>

When this transformation is applied on the following XML document:

<table colspan="3"/>

the wanted, correct result is produced:

<fo:table xmlns:fo="http://www.w3.org/1999/XSL/Format">
   <fo:table-column/>
   <fo:table-column/>
   <fo:table-column/>
</fo:table>