Question

Is it possible to load records from a file straight into a hash please? The records are delimited with /begin and /end, and have a fixed order of content.

What I want is a hash populated like this:

hash_city{London}{slurped_record}='/begin CITY London\n   big\n   England\n   Sterling\n/end CITY'
hash_city{Paris}{slurped_record}='/begin CITY\n   Paris\n   big\n   France\n   Euro\n/end CITY'
hash_city{Melbourne}{slurped_record}='/begin CITY\n\n   Melbourne\n   big\n   Australia\n   Dollar\n   hot\n/end CITY'

I can then go off and process the records in the hash etc.. (reason for the ‘slurped_record’ entry is later I want to add new keys to say London like, ‘country=England’ etc

hash_city{London}{Country}='England'

I’ve managed to achieve something that works by slurping instead of reading the file line-by-line. Matching on a /begin, building up a record ($rec.=$_), then matching on a /end and processing. It’s a bit messy and wondered if there was a more elegant Perl approach..

My code attempt so far is as follows:

use strict;
use warnings;
use Data::Dumper;

my $string = do {local $/; <DATA>};
my %hash_city = map{$2=>$1} $string =~ /(\/begin\s+CITY\s+(\w+).+\/end\s+CITY)/smg;
print Dumper(%hash_city);

__DATA__
stuff
stuff
/begin CITY London
   big
   England
   Sterling
/end CITY

stuff
stuff

/begin CITY
   Paris
   big
   France
   Euro
/end CITY
stuff

/begin CITY

   Melbourne
   big
   Australia
   Dollar
   hot
/end CITY

stuff

Answer 1

Made a little program to show the other way around, advancing your process as well. ) Don’t know whether is’t elegant or not, but I suppose it gets the job done. )

my %city_record;

## we're going to process the input file in chunks.
## here we define the chunk start marker, and make Perl to separate file input with it
local $/ = "/begin CITY";

# ignoring anything before the first section starts
scalar <DATA>;

while (<DATA>) {
  # throwing out anything after the section end marker
  # (might be done with substr-index combo as well, 
  # but regex way was shorter and, for me, more readable as well )
  my ($section_body) = m{^(.+)/end CITY}ms;

  # now we're free to parse the section_body as we want. 
  # showing here pulling city name - and the remaining data, by using the split special case
  my ($city, @city_data) = split ' ', $section_body;

  # filling out all the fields at once
  # (may seem a bit unusual, but it's a simple hash slice actually, great Perl idiom)
  @{ $city_record{$city} }{qw/ size country currency misc /} = @city_data;
}

# just to test, use something of yours instead. )
print Dumper \%city_record;