Question

Is there a way to sort ints that are not in an array?

I know you can use sort(arrayList) type idea with an array but example…

If I have individual variables can a similar task be done? Example, if I have three numbers can I sort them so that they print from largest to smallest?

Thanks!

Answer 1

If your ArrayList holds objects, the type of those objects can implement Comparable so you can use Collections‘ sort method. If you want, you can convert an ArrayList to an array and sort it that way, but it doesn’t look like that’s what you want. Here’s a quick example using both methods:

void setup(){
  int count = 100,now;
  stroke(192,0,0);strokeWeight(count/width);
  //make up some data
  ArrayList<Pair> p = new ArrayList<Pair>();
  for(int i = 0 ; i < count ; i++) {
    Pair pair = new Pair(i,random(10,100));
    p.add(pair);
    float x = map(i,0,count,i,width);
    float y = map(pair.distance,10,100,0,50);
    line(x,50,x,50-y);
  }

  now = millis();

  //Sort typed ArrayList by converting to array first
  println("sort typed array: \n");
  Pair[] s = new Pair[p.size()];
  p.toArray(s);
  Arrays.sort(s);

  println("took " + (millis()-now) + " ms");

  now = millis();

  //Sort using Collections
  println("\n\nsorting typed array list: \n" );
  Collections.sort(p);

  println("took " + (millis()-now) + " ms");

  stroke(0,192,0);
  for(int i = 0 ; i < count ; i++) {
    Pair pair = p.get(i);
    float x = map(i,0,count,i,width);
    float y = map(pair.distance,10,100,0,50);
    line(x,100,x,100-y);
  }

}
class Pair implements Comparable<Pair>{
  public int id;
  public float distance;
  Pair(int i, float d){
    id = i;
    distance = d;
  }
  int compareTo(Pair p){
    if     (p.distance > this.distance) return  1;
    else if(p.distance < this.distance) return -1;
    else return 0;
  }
  String toString(){    return id+":"+distance;    }
}