Question

Is there an easy way to switch out a movieClip for another dynamically loaded movieClip?

I have and eventListener onCLICK that when selected it starts an FLVPlayback but I would also like to swap out with another movieClip Play Now / Now Playing button.

Just some background. I am looping and loading a play button jpg’s into one movie clip and assigning an incremental number as a name to the play button movie clip. On Click that play button plays a movie but now I would also like to switch the play button graphic to a playing now graphic.

//ADD EVENT LISTENER TO ALL MY THUMBS_BUTTON
    thumbs_button.addEventListener (MouseEvent.CLICK, playVideoThumb);

    for (var i:Number = 0; i < my_total; i++) {

        var playButton_url = "play_now.png";
        var playButton_loader = new Loader();
        playButton_loader.name = i;
        playButton_loader.load (new URLRequest(root_path + playButton_url));
        playButton_loader.contentLoaderInfo.addEventListener (Event.COMPLETE, playButtonLoaded);
        playButton_loader.y = (115 * i) + (135 * i) + 138;


//PUT NEW LOADED IMAGE INTO THUMBS_BUTTON
function playButtonLoaded (e:Event):void {
    var my_playButton:Loader = Loader(e.target.loader);
    thumbs_button.addChild (my_playButton);
}


//THIS IS WHERE I NEED TO REMOVE THE PLAY NOW AND PUT IN THE NOW PLAYING BUTTON
function playVideoThumb (e:MouseEvent):void {
    var video_url = root_path +  my_videos[e.target.name].@URL;
    my_player.source = video_url;
    var blank_butt:Number = thumbs_button.getChildByName(e.target.name).x;
    thumbs_button.removeChild(thumbs_button.getChildByName(e.target.name));
}

Answer 1

Looking at your code I assume you probably want a radiobutton like functionality. There a few ways to do this. One way would by removing and adding children or in the case below just using the visible property:

// will contain hidden button
var hidden_button: DisplayObject = null;
// playing now button
var playingNow_button: Loader;

//ADD EVENT LISTENER TO ALL MY THUMBS_BUTTON
thumbs_button.addEventListener (MouseEvent.CLICK, playVideoThumb);

for (var i:Number = 0; i < my_total; i++) {
    var playButton_url: String = "play_now.png";
    var playButton_loader: Loader = new Loader();
    playButton_loader.name = i;
    playButton_loader.load (new URLRequest(root_path + playButton_url));
    playButton_loader.contentLoaderInfo.addEventListener (Event.COMPLETE, playButtonLoaded);
    playButton_loader.y = (115 * i) + (135 * i) + 138;
}
// load playingNow graphic
playingNow_button = new Loader();
playingNow_button.load(new URLRequest(root_path + 'playing_now.png'));
playingNow_button.contentLoaderInfo.addEventListener (Event.COMPLETE, playingNowLoaded);


//PUT NEW LOADED IMAGE INTO THUMBS_BUTTON
function playButtonLoaded (e:Event):void {
    var my_playButton:Loader = Loader(e.target.loader);
    thumbs_button.addChild (my_playButton);
}

//ADD PLAYING_NOW BUT HIDE
function playingNowLoaded (e:Event):void {
    playingNow_button.visible = false;
    thumbs_button.addChild (playingNow_button);
}


//THIS IS WHERE I NEED TO REMOVE THE PLAY NOW AND PUT IN THE NOW PLAYING BUTTON
function playVideoThumb (e:MouseEvent):void {
    // exit if user clicked playing Now button
    if (e.target == playingNow_button) return;
    // also exit if user clicked on something that is not a loader
    if (!(e.target is Loader)) return;
    // show hidden button (if any)
    if (hidden_button != null) hidden_button.visible = true;
    // assign current button to hidden_button
    hidden_button = DisplayObject(e.target);
    // copy location, scale and rotation
    playingNow_button.transform.matrix = hidden_button.transform.matrix;
    // show playingNow and hide button
    playingNow_button.visible = true;
    hidden_button.visible = false;
    // play video
    var video_url = root_path +  my_videos[e.target.name].@URL;
        my_player.source = video_url;
}

If you don’t need any processing of the loaded buttons, you can immediately add the Loader objects to the thumbs_button. You don’t have to do this in the COMPLETE handler.