Question

Is there an inbuilt command to do this or has anyone had any luck with a script that does it?

I am looking to get counts of how many records (as defined by a specific EOL such as “^%!”) had how many occurrences of a specfic character. (sorted descending by the number of occurrences)

For example, with this sample file:

jdk,|ljn^%!dk,|sn,|fgc^%!
ydfsvuyx^%!67ds5,|bvujhy,|s6d75
djh,|sudh^%!nhjf,|^%!fdiu^%!

Suggested input: delimiter EOL and filename as arguments.

bash/perl some_script_name ",|" "^%!" samplefile

Desired output:

occs    count
3        1
2        1
1        2
0        2

This is because the 1st record had one delimiter, 2nd record had 2, 3rd record had 0, 4th record had 3, 5th record had 1, 6th record had 0.

Bonus pts if you can make the delimiter and EOL argument accept hex input (ie 2C7C) or normal character input (ie ,|) .

Answer 1

This is what perl lives for:

#!perl -w
use 5.12.0;

my ($delim, $eol, $file) = @ARGV;

open my $fh, "<$file" or die "error opening $file $!";
$/ = $eol; # input record separator

my %counts;
while (<$fh>) {
    my $matches = () = $_ =~ /(\Q$delim\E)/g; # "goatse" operator
    $counts{$matches}++;
}

say "occs\tcount";
foreach my $num (reverse sort keys %counts) {
    say "$num\t$counts{$num}";
}

(if you haven’t got 5.12, remove the “use 5.12” line and replace the say with print)