Question

Is there any way to get how much memory a service application is using only knowing its service name?

Answer 1

First you must retrieve the Pid of the associated process to the service using the QueryServiceStatusEx function or the Win32_Service WMI Class and then you can use the GetProcessMemoryInfo function to Collect the Memory Usage Information of the process.

Check this sample App

{$APPTYPE CONSOLE}

uses
  ActiveX,
  ComObj,
  Variants,
  Windows,
  psApi,
  SysUtils;

function  GetPidFromService(const ServiceName : string) : DWORD;
const
  WbemUser            ='';
  WbemPassword        ='';
  WbemComputer        ='localhost';
  wbemFlagForwardOnly = $00000020;
var
  FSWbemLocator : OLEVariant;
  FWMIService   : OLEVariant;
  FWbemObjectSet: OLEVariant;
  FWbemObject   : OLEVariant;
  oEnum         : IEnumvariant;
  iValue        : LongWord;
begin;
  FSWbemLocator := CreateOleObject('WbemScripting.SWbemLocator');
  FWMIService   := FSWbemLocator.ConnectServer(WbemComputer, 'root\CIMV2', WbemUser, WbemPassword);
  FWbemObjectSet:= FWMIService.ExecQuery(Format('SELECT ProcessId FROM Win32_Service Where Name="%s"',[ServiceName]),'WQL',wbemFlagForwardOnly);
  oEnum         := IUnknown(FWbemObjectSet._NewEnum) as IEnumVariant;
  if oEnum.Next(1, FWbemObject, iValue) = 0 then
    Result:=FWbemObject.ProcessId;
end;

procedure MemoryInfoService(const ServiceName : string);
var
  hProcess : THandle;
  ppsmemCounters: PPROCESS_MEMORY_COUNTERS;
  cb: DWORD;
begin
  hProcess := OpenProcess(PROCESS_VM_READ or PROCESS_QUERY_INFORMATION, False, GetPidFromService(ServiceName));
  if hProcess <> 0 then
  try
   cb:=SizeOf(PROCESS_MEMORY_COUNTERS);
   GetMem(ppsmemCounters, cb);
   try
   if  GetProcessMemoryInfo( hProcess, ppsmemCounters, cb) then
   begin
      Writeln( Format('PageFaultCount: %d',[ ppsmemCounters.PageFaultCount]));
      Writeln( Format('PeakWorkingSetSize: %d',[ ppsmemCounters.PeakWorkingSetSize]));
      Writeln( Format('WorkingSetSize: %d',[ ppsmemCounters.WorkingSetSize]));
      Writeln( Format('QuotaPeakPagedPoolUsage: %d',[ ppsmemCounters.QuotaPeakPagedPoolUsage]));
      Writeln( Format('QuotaPagedPoolUsage: %d',[ ppsmemCounters.QuotaPagedPoolUsage]));
      Writeln( Format('QuotaPeakNonPagedPoolUsage: %d',[ ppsmemCounters.QuotaPeakNonPagedPoolUsage]));
      Writeln( Format('PagefileUsage: %d',[ ppsmemCounters.PagefileUsage]));
      Writeln( Format('PeakPagefileUsage: %d',[ ppsmemCounters.PeakPagefileUsage]));
   end;
   finally
     FreeMem(ppsmemCounters);
   end;
  finally
    CloseHandle(hProcess);
  end;
end;

begin
 try
    CoInitialize(nil);
    try
      MemoryInfoService('FirebirdGuardianDefaultInstance');
    finally
      CoUninitialize;
    end;
 except
    on E:EOleException do
        Writeln(Format('EOleException %s %x', [E.Message,E.ErrorCode]));
    on E:Exception do
        Writeln(E.Classname, ':', E.Message);
 end;
 Writeln('Press Enter to exit');
 Readln;
end.