Question

Is there any way to have gnuplot color the tic marks in the x and/or y axis? I’m using a background png file which is quite dark and I’d like the inner tics to show in white over it, not the default black.

Answer 1

The tics seem to inherit their color from the border:

set style line 50 lt 1 lc rgb "red" lw 2
set border ls 50
plot sin(x)

The tic labels get their color from the textcolor option of tics:

set tics textcolor rgb "red"

(The string “white” should work too, but that wouldn’t look very nice in my demonstration since my background is white).

There is no way to change just the tic-color. However, if you want, you can change the tic/border color and then add a new border on top:

set arrow from graph 0,graph 1 to graph 1,graph 1 nohead ls -1 lc rgb "black" front
set arrow from graph 1,graph 1 to graph 1,graph 0 nohead ls -1 lc rgb "black" front
set arrow from graph 1,graph 0 to graph 0,graph 0 nohead ls -1 lc rgb "black" front
set arrow from graph 0,graph 0 to graph 0,graph 1 nohead ls -1 lc rgb "black" front