Question

I’ve a vb .net winform that is show by others forms. I’ve frmA.vb, frmB.vb, frmC.vb and frmD.vb.

This all forms can call frmItem.vb.
frmItem.vb allows the user to select an item from a Database, this item is sent by calling a Set Property on the parent.

i.e.

I open frmA, click on button (something like:)

  fi = new frmItem(frmA) 'frmItem has 4 New() methods, frmA.. b... c and d
  'i need to pass the correct parent.
  fi.showModal()

So, when i add an item, it calls

  fA.addItem(item_id)

It works OK, my doubt is about optimization, because i’ve duplicated frmItem; one copy managed frmA and frmB, and the other one, frmC and frmD.

i.e.

in frmItem1 when i’ve to sent the item, i use:

private fB as frmB
private fA as frmA



if parentFrmA is nothing then
   'Is frmB
   fB.addItem(item_id)
else
   'Is frmA
   fA.addItem(item_id)
end if

And, on frmItem2:

private fC as frmC
private fD as frmD



if parentFrmC is nothing then
   'Is frmD
   fD.addItem(item_id)
else
   'Is frmC
   fC.addItem(item_id)
end if

If i modify frmItem1, i’ve to modify frmItem2 and viceversa, because they should look and act like one.

All four forms, have the same Set Property, but like they’re differents forms, i can’t use a unique Form class in frmItem.

Is the posibility that one form, can manage multi parents in an easy way??

If you need more info, let me know. Thanks

Answer 1

I can’t completely follow your example since, well, I think it’s just hard to follow.

But in general, it sounds like these child forms should just be raising an event that the parent form is listening for. That way, you can separate your concerns a bit and not hardcode these dependencies.

You can try making your own EventArgs class to follow best practices:

Public Class ChildFormEventArgs
  Inherits EventArgs

  Private _ItemID As Integer

  Public Sub New(ByVal itemID As Integer)
    _ItemID = itemID
  End Sub

  ReadOnly Property ItemID() As Integer
    Get
      Return _ItemID
    End Get
  End Property
End Class

Your child forms would have a public event and you would raise it when ever this “added” thing happens:

Public Class Form2
  Public Event ItemAdded(ByVal sender As Object, ByVal e As ChildFormEventArgs)

  Private _ItemID as Integer

  Private Sub Button1_Click(ByVal sender As Object, ByVal e As EventArgs) Handles Button1.Click
    RaiseEvent ItemAdded(Me, New ChildFormEventArgs(_ItemID))
  End Sub
End Sub

And then your parent form is the one listening and can act accordingly:

Private Sub Button1_Click(ByVal sender As Object, ByVal e As EventArgs) Handles Button1.Click
  Using testForm As New Form2()
    AddHandler testForm.ItemAdded, AddressOf ChildForm_ItemAdded
    testForm.ShowDialog(Me)
    RemoveHandler testForm.ItemAdded, AddressOf ChildForm_ItemAdded
  End Using
End Sub

Private Sub ChildForm_ItemAdded(ByVal sender As Object, ByVal e As ChildFormEventArgs)
  '// do something here.
  '// sender is the child form that called it
  '// e is the event arguments that contains the ItemID value
End Sub