Question

I’ve been struggling with a Flash preloader. I just want it to update the text on the screen with the current percentage. Now it basically works as the trace outputs the correct percentages, but it won’t update the textfield I have on the screen. Once the trace gets to 100% however, the code does output “100” on the screen, but not until it’s all loaded. I don’t have the Flash IDE and am just using pure Actionscript with FlashDevelop. Here’s my code:

package 
{
  import flash.display.Sprite;
  import flash.events.Event;
  import flash.display.Loader;
  import flash.events.ProgressEvent;
  import flash.net.URLRequest;
  import flash.net.URLLoader;
  import flash.display.Loader; 
  import flash.text.TextField;
  import flash.text.TextFormat;
  import flash.text.TextFieldType;


  public class Main extends Sprite 
  {
    public var myLoader:Loader = new Loader();
    public var image:String = "tmp/Avengers-poster.jpg";


    private var Title:TextField;
    private var txt:String;
    private var Form:TextField;

    public function Main():void {
      textbox("This is the title","box",100,100,200,30);

      myLoader.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS, onProgressStatus);
      myLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, onLoaderReady);

      var fileRequest:URLRequest = new URLRequest(image);
      myLoader.load(fileRequest);           
    }

    public function onProgressStatus(e:ProgressEvent):void {   
        // this is where progress will be monitored     
        var perc:int = Math.ceil((e.bytesLoaded/e.bytesTotal)*100);
        txt = perc.toString();
        Title.text = txt;
        addChild (Title);
        trace(perc); 
    }

    public function onLoaderReady(e:Event):void {     
        // the image is now loaded, so let's add it to the display tree!     
        addChild(myLoader);
    }   

    private function textbox (title_str:String,form_name:String,x:int,y:int,width:int,height:int):void {

       Title = new TextField ();
       Title.text = title_str;
       Title.selectable = false;
       Title.setTextFormat (new TextFormat ("Arial", 12, 0x777777, true));

       txt = ".";

       Title.x = x;
       Title.y = y;
       addChild (Title);
    }       

  }

}

Thanks for your help.

Darryl

Answer 1

This will work. Don’t recreate the TextField on each status. You only need to addChild once and update the reference to it.

package 
{
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.ProgressEvent;
    import flash.net.URLLoader;
    import flash.net.URLRequest;
    import flash.text.TextField;
    import flash.text.TextFieldType;
    import flash.text.TextFormat;   

    public class Main extends Sprite 
    {
        public var myLoader:Loader = new Loader();
        public var image:String = "http://apod.nasa.gov/apod/image/0605/titan5km_huygens_big.jpg";

        private var Title:TextField;
        private var Form:TextField;

        public function Main():void {

            createTextField("This is the title","box",100,100,200,30);

            myLoader.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS, onProgressStatus);
            myLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, onLoaderReady);

            var fileRequest:URLRequest = new URLRequest(image);
            myLoader.load(fileRequest);           
        }

        public function onProgressStatus(e:ProgressEvent):void {   
            // this is where progress will be monitored     
            var perc:int = Math.ceil((e.bytesLoaded/e.bytesTotal)*100);
            Title.text = perc.toString();
        }

        public function onLoaderReady(e:Event):void {     
            // the image is now loaded, so let's add it to the display tree!     
            addChild(myLoader);
        }   

        private function createTextField (title_str:String,form_name:String,x:int,y:int,width:int,height:int):void {

            Title = new TextField();
            Title.text = title_str;
            Title.selectable = false;
            Title.setTextFormat (new TextFormat ("Arial", 12, 0x777777, true));

            Title.text = ".";

            Title.x = x;
            Title.y = y;

            addChild (Title);
        }       

    }   
}