Question

I’ve been trying to get System Events to duplicate files in AppleScript and I’ve been failing 🙂 I eventually always get the error “error “Files can not be copied.” number -1717″. So I changed my tactics and tried using the Finder to make sure what i was trying to do was correct. Here is the code that works:

tell application “System Events”

set desktopFolder to (path to desktop folder) as string
set fullPath to desktopFolder & "Temp Export From DO"

set theDOEntries to every file of folder "/Users/jkratz/Dropbox/Apps/Day One/Journal.dayone/entries" whose name extension is "doentry"
repeat with DOEntry in theDOEntries
    set source to path of DOEntry
    log "Source file: " & source
    set destination to fullPath as string
    log "Destination folder: " & destination
    tell application "Finder"
        duplicate file source to folder destination with replacing
    end tell
end repeat

end tell

If I remove that last tell, so that it uses System Events, I get the same error noted above. The dictionary for System Events standard suite has a “duplicate” command so I’m not sure what is going on here. Also, “Learning AppleScript, 3rd ed” from APress notes:

“One particularly annoying omission in System Events is that it can’t yet duplicate files and folders; if you need to do this, the Finder is your best bet.”

The 3rd edition is from 2010. It would seem that even in Mountain Lion this is still true. Can anyone confirm this? The 1717 error number lists everywhere else as a handler error and i’m not using handlers.

Answer 1

Try:

tell application "Finder" to set desktopFolder to (path to desktop folder as text) & "Temp Export From DO" as alias
tell application "System Events" to set theDOEntries to every file of folder "/Users/jkratz/Dropbox/Apps/Day One/Journal.dayone/entries" whose name extension is "doentry"
repeat with DOEntry in theDOEntries
    log "Source file: " & DOEntry
    log "Destination folder: " & desktopFolder
    tell application "Finder" to duplicate file DOEntry to desktopFolder with replacing
end repeat

If you don’t need to log the values you can simply:

tell application "Finder" to set desktopFolder to (path to desktop folder as text) & "Temp Export From DO" as alias
tell application "System Events" to set theDOEntries to every file of folder "/Users/jkratz/Dropbox/Apps/Day One/Journal.dayone/entries" whose name extension is "doentry"
tell application "Finder" to duplicate theDOEntries to desktopFolder with replacing

Or:

set desktopFolder to quoted form of (POSIX path of (path to desktop folder as text) & "Temp Export From DO")
do shell script "find '/Users/jkratz/Dropbox/Apps/Day One/Journal.dayone/entries' -name \"*.doentry\" -type f -print0 | xargs -0 -I {} cp -a {} " & desktopFolder

Getting back to your question, the duplicate commands creates duplicates of Finder items. You can use System Events to duplicate Finder items like this:

tell application "Finder"
    set myFile to file ((path to desktop as text) & "Test File.txt")
    set myFolder to folder ((path to desktop as text) & "Test Folder")
end tell

tell application "System Events"
    duplicate myFile to myFolder
end tell