Question

I’ve found configure about autocompleting brackets,

inoremap ' ''<Left>
inoremap " ""<Left>
inoremap { {}<Left>
inoremap ( ()<Left>

but when I tried to delete the ‘(‘, the ‘)’ stays, but in Sublime Text 2, that would disappear too. So how can I configure .vimrc ro make that?

// Update: got the vim-autoclose plugin, seems work now.

Answer 1

If you install surround.vim you can do this by using

inoremap ' ''<Left>
inoremap " ""<Left>
inoremap { {}<Left>
inoremap ( ()<Left>

imap <expr> <C-h> "\<C-\>\<C-n>x".((col('.')==col('$'))?(""):("h"))."a"
imap <BS>  <C-h>
let s:pairsymbols={"'": "'",
            \      '"': '"',
            \      '{': '}',
            \      '(': ')',}
function! s:DelPair()
    let cnt=v:count1
    if col('$')==1
        let shiftline=(line('.')<line('$'))
        normal! dd
        if shiftline
            normal! k
        endif
        normal! $
        if cnt>1
            execute 'normal '.(cnt-1).'x'
        endif
        return
    endif
    let curch=getline('.')[col('.')-1]
    if has_key(s:pairsymbols, curch)
        let oldchtick=b:changedtick
        if getline('.')[col('.')] is# s:pairsymbols[curch]
            normal! 2x
        else
            execute "normal \<Plug>Dsurround".s:pairsymbols[curch]
            if b:changedtick==oldchtick
                normal! x
            endif
        endif
    else
        normal! x
    endif
    if cnt>1
        execute 'normal '.(cnt-1).'x'
    endif
endfunction
nnoremap x :<C-u>call <SID>DelPair()<CR>