Question

I’ve got a DataGridView in a vb.net form, not connected to any source. I want to remove a row when the user pass to another row or focus out the DGV. The row should be removed if there’s an empty cell in it.

That’s my code:

Private Sub dgvSpSettings_RowLeave(sender As Object, e As System.Windows.Forms.DataGridViewCellEventArgs) Handles dgvSpSettings.RowLeave
    If e.RowIndex < (dgvSpSettings.Rows.Count - 1) Then 'Esclude l'ultima riga dal controllo sulle righe vuote
        If Me.dgvSpSettings.Rows(e.RowIndex).Cells(0).Value Is Nothing OrElse Me.dgvSpSettings.Rows(e.RowIndex).Cells(0).Value.ToString() = "" OrElse Me.dgvSpSettings.Rows(e.RowIndex).Cells(1).Value Is Nothing OrElse Me.dgvSpSettings.Rows(e.RowIndex).Cells(1).Value.ToString() = "" Then
            Me.dgvSpSettings.Rows.RemoveAt(e.RowIndex)
        End If
    End If
End Sub

This doesn’t work because I can’t perform the method Me.dgvSpSettings.Rows.RemoveAt(e.RowIndex) in this event. I tried to store the row in a private var and then delete it in other events (like click), but the result is not what I expected.

Any suggestions?

Answer 1

That’s my final solution. It works for me and I hope it’s conceptually correct. I used delegates and Leave + LostFocus events.

'**********
'* Controllo righe da eliminare
'**********
Private Sub dgvSpSettings_RowLeave(sender As Object, e As System.Windows.Forms.DataGridViewCellEventArgs) Handles dgvSpSettings.RowLeave
    Me.dgvSpSettings.CommitEdit(0)

    Dim row As DataGridViewRow = Me.dgvSpSettings.Rows(e.RowIndex)

    For Each cell In row.Cells
        cell.Style.BackColor = Color.White
    Next

    If Not row.IsNewRow() Then 'Esclude l'ultima riga dal controllo sulle righe vuote
        If String.IsNullOrEmpty(row.Cells(0).Value) OrElse String.IsNullOrEmpty(row.Cells(1).Value) Then
            _rowBlank = row
        End If
    End If

End Sub

Private Delegate Sub setCurrentCellDelegate()

Private Sub setCurrentCell()
    For Each cell In _rowBlank.Cells
        cell.Style.BackColor = Color.LightSalmon
    Next

    Me.dgvSpSettings.CurrentCell = _rowBlank.Cells(0)
    Me.dgvSpSettings.BeginEdit(True)
    _rowBlank = Nothing
End Sub

Private Delegate Sub removeRowDelegate()

Private Sub removeRow()
    Me.dgvSpSettings.Rows.Remove(_rowBlank)
    _rowBlank = Nothing
    _rowBlankDeleting = False
End Sub

'**********
'* Controllo righe da eliminare
'**********
Private Sub dgvSpSettings_Leave(sender As Object, e As System.EventArgs) Handles dgvSpSettings.Leave
    If _rowBlank IsNot Nothing AndAlso _rowBlankDeleting = False Then
        If MsgBox("Alcuni campi della riga non sono stati valorizzati. Eliminare la riga?", vbYesNo + vbInformation, "Eliminare") = MsgBoxResult.Yes Then
            _rowBlankDeleting = True
            Me.dgvSpSettings.BeginInvoke(New removeRowDelegate(AddressOf removeRow))
        Else
            Me.dgvSpSettings.BeginInvoke(New setCurrentCellDelegate(AddressOf setCurrentCell))
        End If
    End If
End Sub

'**********
'* Controllo righe da eliminare
'**********
Private Sub dgvSpSettings_LostFocus(sender As Object, e As System.EventArgs) Handles dgvSpSettings.LostFocus
    If _rowBlank IsNot Nothing AndAlso _rowBlank IsNot Me.dgvSpSettings.CurrentRow AndAlso _rowBlankDeleting = False Then
        If MsgBox("Alcuni campi della riga non sono stati valorizzati. Eliminare la riga?", vbYesNo + vbInformation, "Eliminare") = MsgBoxResult.Yes Then
            _rowBlankDeleting = True
            Me.dgvSpSettings.BeginInvoke(New removeRowDelegate(AddressOf removeRow))
        Else
            Me.dgvSpSettings.BeginInvoke(New setCurrentCellDelegate(AddressOf setCurrentCell))
        End If
    End If
End Sub