Question

I’ve got a dynamic text field in my button object. I have named the text field “myText”. How can I modify the text within it? myButton.myText.text = "test"; won’t work, because it can’t access myText.

Answer 1

I usually just create a MovieClip that contains a blank button and a dynamic text field.
If you set mouseEnabled = false on the text field, it won’t interfere with the mouse events on the button.

Edit:
Here’s and example of a custom button class I use sometimes:

package {

import flash.display.MovieClip;
import flash.events.MouseEvent;
import flash.text.TextField

public class CustomButton extends MovieClip {

    public var t_label:TextField; 

    public function CustomButton() {
        t_label.mouseEnabled = false;
        mouseChildren = false;
        buttonMode = true;

        this.gotoAndStop("normal");
        addEventListener(MouseEvent.MOUSE_OVER, onMouseOver);
        addEventListener(MouseEvent.MOUSE_OUT, onMouseOut);
        addEventListener(MouseEvent.MOUSE_DOWN, onMouseDown);
    }

    public function setLabel(buttonLabel:String):void {
        t_label.text = buttonLabel;
    }

    public function destroy():void {
        removeEventListener(MouseEvent.MOUSE_OVER, onMouseOver);
        removeEventListener(MouseEvent.MOUSE_OUT, onMouseOut);
        removeEventListener(MouseEvent.MOUSE_DOWN, onMouseDown);
    }

    protected function onMouseOver(e:MouseEvent):void {
        this.gotoAndStop("over");
    }

    protected function onMouseOut(e:MouseEvent):void {
        this.gotoAndStop("normal");
    }

    protected function onMouseDown(e:MouseEvent):void {
        this.gotoAndPlay("down");
    }

}   

}

You can link this to a MovieClip that has frames labeled “normal”, “over” and “down” and it will function like a normal button with a dynamic label.

If you need to customize the text appearance for the different states you can do so within the event handlers.