Question

I’ve got a problem about to write a function to find the longest word in a text.

Input: A string with a lot of word. Ex: "I am a young man, and I have a big house."

The result will be 5 because the longest words in the text have 5 letters (young and house).

I’ve just started to learn Haskell. I’ve tried:

import Char
import List

maxord' (str:strs) m n = 
    if isAlpha str == True
    then maxord'(strs m+1 n)
else    if m >= n
        then maxord'(strs 0 m)
    else    maxord'(strs 0 n)

maxord (str:strs) = maxord' (str:strs) 0 0

I want to return n as the result but I don’t know how to do it, and it seems there is also something wrong with the code.

Any help? Thanks

Answer 1

There are several issues here. Let’s start with the syntax.

Your else parts should be indented the same or more as the if they belong to, for example like this:

if ...
then ...
else if ...
     then ...
     else ...

Next, your function applications. Unlike many other languages, in Haskell, parentheses are only used for grouping and tuples. Since function application is so common in Haskell, we use the most lightweight syntax possible for it, namely whitespace. So to apply the function maxord' to the arguments strs, m+1 and n, we write maxord' strs (m+1) n. Note that since function application has the highest precedence, we have to add parentheses around m+1, otherwise it would be interpreted as (maxord' strs m) + (1 n).

That’s it for the syntax. The next problem is a semantic one, namely that you have recursion without a base case. Using the pattern (str:strs), you have specified what to do when you have some characters left, but you’ve not specified what to do when you reach the end of the string. In this case, we want to return n, so we add a case for that.

maxord' [] m n = n

The fixed maxord' is thus

maxord' [] m n = n
maxord' (str:strs) m n = 
    if isAlpha str == True
    then maxord' strs (m+1) n
    else if m >= n
         then maxord' strs 0 m
         else maxord' strs 0 n

---

However, note that this solution is not very idiomatic. It uses explicit recursion, if expressions instead of guards, comparing booleans to True and has a very imperative feel to it. A more idiomatic solution would be something like this.

maxord = maximum . map length . words

This is a simple function chain where words splits up the input into a list of words, map length replaces each word with its length, and maximum returns the maximum of those lengths.

_{Although, note that it’s not the exact same as your code, since the words function uses slightly different criteria when splitting the input.}