Question

I’ve got a question in my test:

What is wrong with program that counts number of lines and words in file?

open F, $ARGV[0] || die $!;
my @lines = <F>;
my @words = map {split /\s/} @lines;
printf "%8d %8d\n", scalar(@lines), scalar(@words);
close(F); 

My conjectures are:

1. If file does not exist, program won’t tell us about that.

2. If there are punctuation signs in file, program will count them, for example, in

   abc cba
   , , ,dce
   

   will be five word, but on the other hand wc outputs the same result, so it might be considered as correct behavior.

3. If F is a large file, it might be better to iterate over lines and not to dump it into lines array.

Do you have any less trivial ideas?

Answer 1

On the first line, you have a precedence problem:

open F, $ARGV[0] || die $!;

is the same as

open F, ($ARGV[0] || die $!);

which means the die is executed if the filename is false, not if the open fails. You wanted to say

open(F, $ARGV[0]) || die $!;

or

open F, $ARGV[0] or die $!;

Also, you should be using the 3 argument form of open, in case $ARGV[0] contains characters that mean something to open.

open F, '<', $ARGV[0] or die $!;

On a different note, splitting on /\s/ means that you get a “word” between consecutive whitespace characters. You probably meant /\s+/, or as amphetamachine suggested, /\W+/, depending on how you want to define a “word”.

That still leaves the problem of the empty “word” you get if the line begins with whitespace. You could split on ' ' to suppress that (it’s a special case), or you could trim leading whitespace first, or insert a grep { length $_ } to weed out empty “words”, or abandon split and use a different method for counting words.

Processing line by line instead of reading the whole file at once would also be a good improvement, but it’s not as important as those first two items.