Question

I’ve got a static property I would like to access by importing it’s class without instantiating an object of that class. Is this possible?

Essentially I’m writing a bunch of styleSheet Objects over and over. I figure If I have a class called CSS and like this:

package com
{
    import flash.text.*;

   public class CSS
   {  

    public static var STYLE_SHEET:StyleSheet = new StyleSheet();

and assign all of it’s properties in the constructor like:

public function CSS
   {
          //NAV BUTTON
        var navButtonBlock:Object = new Object();
        navButtonBlock.color = "#000000";
        navButtonBlock.fontSize = "25";
        navButtonBlock.fontFamily = "Arial";
        navButtonBlock.marginLeft = "5";
        navButtonBlock.kerning = "true";
        navButtonBlock.fontWeight = "bold";

        //TITLE
        var titleBlock:Object = new Object();
        titleBlock.color = "#CCCCCC";
        titleBlock.fontSize = "25";
        titleBlock.fontFamily = "Arial";
        titleBlock.marginLeft = "5";
        titleBlock.kerning = "true";
        titleBlock.fontWeight = "bold";

        STYLE_SHEET.setStyle("code", titleBlock);
        STYLE_SHEET.setStyle("navButton", navButtonBlock);
}

If I import the class into the class I wish to make use of it like:

package{
 import com.CSS;

and inside my class use the variable like:

textField.styleSheet = CSS.STYLE_SHEET;

I can save some headaches.
The thing I find weird is that I have create an instance of that class to access it’s const. So in the class header I have to write:

private var css:CSS = new CSS();

even though I never end up making use of this object…
Does this make sense? Am I going about this the wrong way?

-J
p.s. Who wishes the tab key worked in this question editor window?

Answer 1

You can write static init() function, which you will have call only once or you can use “static initializers”:

package com
{
   import flash.text.*;

   public class CSS
   {  
       public static var STYLE_SHEET:StyleSheet = new StyleSheet();

       // Static init block
       // This block is run once when the class is first accessed
       {
           var navButtonBlock:Object = new Object();
           /*...*/
           var titleBlock:Object = new Object();
           /*...*/
           STYLE_SHEET.setStyle("code", titleBlock);
           STYLE_SHEET.setStyle("navButton", navButtonBlock);
        }
    }
}

Now import class and just use static var STYLE_SHEET

import com.CSS;
...
textField.styleSheet = CSS.STYLE_SHEET;