Question

I’ve got an algorithm that selects a cell in a 3d array and then reads or writes the data wich is a reference to another 3d array. Think of it as a “minecraft” algorithm.
The problem is i have no idea how to make a data structure in Perl that works like this : @3darray(x,y,z) = value
Can you help me?

Answer 1

If I understand correctly:

use Data::Dumper;

my ($x, $y, $z) = (1, 2, 3);
my @array = map [map [map 0, 1..$z], 1..$y], 1..$x;

print Dumper \@array;

Output:

$VAR1 = [
          [
            [
              0,
              0,
              0
            ],
            [
              0,
              0,
              0
            ]
          ]
        ];

However, there’s no need to make this structure beforehand, since Perl creates it for you through autovivification (see reference further down) when you access an element in the nested structure:

use Data::Dumper;

my @array;
$array[0][0][2] = 3;

print Dumper \@array;

Output:

$VAR1 = [
          [
            [
              undef,
              undef,
              3
            ]
          ]
        ];

From perlglossary:

autovivification

A Greco-Roman word meaning "to bring oneself to life". In Perl, storage locations
(lvalues) spontaneously generate themselves as needed, including the creation of
any hard reference values to point to the next level of storage. The assignment
$a[5][5][5][5][5] = "quintet" potentially creates five scalar storage locations,
plus four references (in the first four scalar locations) pointing to four new
anonymous arrays (to hold the last four scalar locations). But the point of
autovivification is that you don't have to worry about it.

As for looping, if you need indexes:

for my $i (0 .. $#array) {
    for my $j (0 .. $#{$array[$i]}) {
        for my $k (0 .. $#{$array[$i][$j]}) {
            print "$i,$j,$k => $array[$i][$j][$k]\n";
        }
    }
}

Otherwise:

for (@array) {
    for (@$_) {
        for (@$_) {
            print "$_\n";
        }
    }
}