Question

I’ve made a function called FormatDT, and I put it on \include\basic_function.asp

here is the code of that function:

function FormatDT(ddate,format)
        ddate = cdate(ddate)
        Set re = New RegExp
        re.Pattern = "%."
        re.Global = True
        re.IgnoreCase = False
        're.MultiLine = True
        set matches = re.execute(format)
        hasil = ""
        tmp = format
        for each match in matches
            fmt = match.value
            select case fmt
                case "%d" hasil = day(ddate)
                case "%D" hasil = right("00" & day(ddate),2)
                case "%m" hasil = month(ddate)
                case "%M" hasil = right("00" & month(ddate),2)
                case "%b" hasil = left(MonthName(month(ddate)),3)
                case "%B" hasil = MonthName(month(ddate))
                case "%y" hasil = right(year(ddate),2)
                case "%Y" hasil = year(ddate)
                case "%h" hasil = hour(ddate)
                case "%H" hasil = right("00" & hour(ddate),2)
                case "%n" hasil = minute(ddate)
                case "%N" hasil = right("00" & minute(ddate),2)
                case "%s" hasil = second(ddate)
                case "%S" hasil = right("00" & second(ddate),2)
                case else hasil = replace(fmt,"%","")
            end select
            tmp = replace(tmp,fmt,hasil)
        next
        FormatDT = tmp
    end function

I use this function in here:

<input style="text-align:center" class="label" style="width:6em;" type="text" id="txtDate" name="txtDate" size="12" value="<%=FormatDt(dtglvalid,"%M/%D/%Y")%>" >

and when I load the page, I got error message like this:

Microsoft VBScript runtime error ‘800a005e’ Invalid use of Null: ‘cDate’
/include/basic_function.asp, line 234

line 234 located on ddate = cdate(ddate)

how to solve this error?

Answer 1

ASP is complaining about the variable ddate being NULL. Looking at you code, it looks like the variable dtglvalid is NULL which is passed to the function and causes the error. You could do something like:

<input ... value="<% if not IsNull(dtglvalid) then Response.Write FormatDt(dtglvalid,"%M/%D/%Y") %>">