Question

I’ve written a small assember program that gets and input file, an output file and an alternative parameter (either -a or -l).
Now I want to distinguis in the program if the user has passed a -a or -l. I know I can pass the parameter into, e.g %eax like follows:

movl 16(%ebp),%eax

But now I don’t know how to compare %eax with -a or with -l to check what parameter was passed.
The program runs on a 32-bit Linux OS.

Can anyone give me a hint please?

Thanks in advance,

enne

EDIT: I have a x86-processor. Here are some relevant parts of the code

 .section .data 
#######PROGRAM CODE###

.section .text

#STACK POSITIONS
.equ ST_SIZE_RESERVE, 8
.equ ST_FD_IN, 0
.equ ST_FD_OUT, 4
.equ ST_ARGC, 8      #Number of arguments
.equ ST_ARGV_0, 12   #Name of program
.equ ST_ARGV_1, 16   #Input file name
.equ ST_ARGV_2, 20   #Output file name
.equ ST_ARGV_3, 24   #-a or -l or nothing
.equ ST_EXIT_CODE, 28   #Exit code

.globl _start
_start:
###INITIALIZE PROGRAM###
subl  $ST_SIZE_RESERVE, %esp       #Allocate space for our pointers on the stack
movl  %esp, %ebp

### Set standard error code 0
movl $0, %ebx
movl %ebx, ST_EXIT_CODE(%ebp)
    movl ST_ARGV_3(%ebp),%eax  #eax contains now the alternative paramter

Answer 1

In “C” what you want to do is:

if (strcmp(argv[3], "-a") == 0) {
   /* stuff here */
}

Since you’re working without the C standard library you have to create strcmp yourself. This isn’t too difficult as it amounts to:

int strcmp(const char* str1, const char* str2) {
    while (*str1 && *str1 == *str2) { 
        str1++;
        str2++;
    }
    return *str1 - *str2;
}

Or in assembly:

strcmp:
    push %ebp
    mov %esp, %ebp
    movl 0x8(%ebp), %esi # str1
    movl 0xc(%ebp), %edi # str2
1:
    movb (%esi), %al
    or %al, %al # *str1 zero?
    jz 2f
    movb (%edi), %ah
    cmp %ah, %al # equal to *str2?
    jne 2f
    # move to next character
    inc %esi
    inc %edi
    jmp 1b
2:
    # result is difference between the two characters compared
    movb (%esi), %al
    subb (%edi), %al
    movsx %al, %eax # Sign-extend to 32-bits
    pop %ebp
    ret

Of course if you’re not actually using the computed difference between the strings (it’s useful for sorting) you can simplify the procedure slightly.

And using it:

    # [snip]
    movl ST_ARGV_3(%ebp),%eax  #eax contains now the alternative paramter

    push %eax      # first argument
    pushl $dasha   # second argument "-a"
    call strcmp    # compare strings
    add $8, %esp   # pop arguments

    cmpl $0, %eax  # Strings equal?
    je strings_are_equal  # Subtitute your own logic here
    jmp strings_are_not_equal # and here..

Note that this assumes that you have a string to compare against placed in your data section like:

.section .data 
dasha: .asciz "-a"