Question

Let’s assume I have following XML:

<element1 title="title1">
<element2 title="title2">
<element3 title="title1">

Here attribute title is duplicated for element1 and element3. I would like to find all elements with duplicated title and replace title values with names of elements. So, the example above would be:

<element1 title="element1">
<element2 title="title2">
<element3 title="element3">

How is it possible to do with XSLT 1.0 ?

Answer 1

I. This transformation:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match=
  "@title[. = ../preceding::*/@title
         or
          . = ../following::*/@title
          ]">
  <xsl:attribute name="title"><xsl:value-of select="name(..)"/></xsl:attribute>
 </xsl:template>
</xsl:stylesheet>

when applied on the following XML document:

<t>
    <element1 title="title1"/>
    <element2 title="title2"/>
    <element3 title="title1"/>
</t>

produces the wanted, correct result:

<t>
   <element1 title="element1"/>
   <element2 title="title2"/>
   <element3 title="element3"/>
</t>

---

II. A probably more efficient solution using keys:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:key name="kTitleVyVal" match="@title" use="."/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match=
  "@title[key('kTitleVyVal', .)[2]]">
  <xsl:attribute name="title"><xsl:value-of select="name(..)"/></xsl:attribute>
 </xsl:template>
</xsl:stylesheet>