Question

Let’s say I have an XML node like the following:

<item id="20">
    <name>Baz</name>
    <description>
        If you liked this, you should check out <related id="5">Foo</related>
        and <related id="7">Bar</related>!
    </description>
<item>

When outputting the description via XSLT, I want the text() to be rendered such that each of the <related> nodes become anchor tags. How would I go about doing this?

Edit: Desired output added per Kirill’s request. I’d like it to look something like this:

If you liked this, you should check out <a href=”/items/5″>Foo<a> and <a href=”/items/7″>Bar<a>!

Answer 1

Create a template that overrides the default handling for related elements:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="related">
        <a href="/items/{@id}"><xsl:value-of select="."/></a>
    </xsl:template>
</xsl:stylesheet>

Output:

<item id="20">
    <name>Baz</name>
    <description>
        If you liked this, you should check out <a href="/items/5">Foo</a>
        and <a href="/items/7">Bar</a>!
    </description>
</item>

This is a fundamental XSLT pattern. The first template implements the Identity Transform, which copies most nodes through unchanged. The second template overrides the first in the case of related elements, converting them to HTML anchors.