Question

My Air 2.5 application needs to save some text files inside some custom folder.

Currently i am using documents folder to save files (using FileStream), which works fine. But i need to save it inside any folder.

Is there a way to save files in any targeted folder? (using FileStream)

Answer 1

I have got the working solution. It saves file to your targeted folder. It might help you.

/*Requires AIR 2.5 (May be AIR 2.0. I have not tested) and Flash CS6.*/
import flash.filesystem.*;
import flash.utils.ByteArray;

//Sample XMl
var xml:XML = <audio>song1.mp3</audio>;
var outputString:String = '<?xml version="1.0" encoding="utf-8"?>\n';
outputString +=  xml.toXMLString();
outputString = outputString.replace(/\n/g,File.lineEnding);

//Byte array
var xmlData:ByteArray = new ByteArray();
xmlData.writeUTFBytes(outputString);

//Targeted custom folder
var urlStr:String = "file:///D:/Temp/"; // you can get this URL from external text file
var audioXMLFile:File = new File();
audioXMLFile.url = urlStr;
audioXMLFile = audioXMLFile.resolvePath("SongList.xml");

//File stream
var outStream:FileStream = new FileStream();
outStream.addEventListener(Event.CLOSE, dataSaved, false, 0, true);
outStream.addEventListener(OutputProgressEvent.OUTPUT_PROGRESS, savingProgress, false, 0, true);

//open output file stream in WRITE mode
outStream.openAsync(audioXMLFile, FileMode.WRITE);

//write out the file
outStream.writeBytes(xmlData, 0, xmlData.length);

//Saving progress
function savingProgress(e:OutputProgressEvent):void
{
    if (e.bytesPending == 0)
    {
        //Close stream on save
        e.target.close();
    }
}

// 
function dataSaved(e:Event):void
{
    trace("File Saved");
}