Question

My animation is 100 frames total. I want to set a range of frames. Is is there a command to play only frames 50 to 75? I want begin-and-end frame to be in an object I can call on later. There must be a “best” way of doing this!

100 frame total
<==play 50 to 75==>

SAMPLE

    These commands work, but I would end up adding labels and stop();

//start playing at given frame
Play at 9950.00
gotoAndPlay(4990,"Scene 1");

//advance and stop at given frame
my_mc.gotoAndStop(my_mc.currentFrame + 10);

//control frame rate on stage
Frame rate command
stage.frameRate = 90;

USE

The begin-and-end of my movie should be an object in it’s self. My movie will need to control time and duration for a given number of frames. Comment if you have any ideas.

TAGS

AS 3.0, timer class, display, time-scaling

Patricks example modified “I play with the values, but no effect or error”

  import flash.display.MovieClip; 
  import fl.transitions.Tween; 
  import fl.transitions.easing.*; 

    //... 

    function playFromTo(from:int, to:int, duration:Number):Tween { 

      return new Tween(this, "tweenFrame", None.easeNone, from, to, duration, true); 
    } 

    //instance of tweenFrame on stage
    var _tweenFrame:Number; 
    function set tweenFrame(value:Number):void{ 

    //what about value?
      _tweenFrame = value; 
      gotoAndStop(int(value)); 
    } 
    function get tweenFrame():Number{ 
      return _tweenFrame; 
    } 

Answer 1

If you want to control time, acceleration, etc… You can use a tween to advance the play head, add a getter and setter that will change the play head.

For this example i use the flash tweening but you can use whatever library you want.

package  {
  import flash.display.MovieClip;
  import fl.transitions.Tween;
  import fl.transitions.easing.*;

  public class MyMC extends MovieClip { 
    //...

    public function playFromTo(from:int, to:int, duration:Number):Tween {
      // add a tween with no acceleration and a duration in second
      return new Tween(this, "tweenFrame", None.easeNone, from, to, duration, true);
    }

    private var _tweenFrame:Number;
    public function set tweenFrame(value:Number):void{
      _tweenFrame = value;
      gotoAndStop(int(value));
    }
    public function get tweenFrame():Number{
      return _tweenFrame;
    }
  }
}

or using composition if you cant modify your MovieClip:

package  {
  import flash.display.MovieClip;
  import fl.transitions.Tween;
  import fl.transitions.easing.*;

  public class TweenableMC {
    private var _target:MovieClip;

    public function TweenableMC(target:MovieClip):void {
      _target=target;
    }

    public function playFromTo(from:int, to:int, duration:Number):Tween {
      // add a tween with no acceleration and a duration in second
      return new Tween(_target, "tweenFrame", None.easeNone, from, to, duration, true);
    }

    private var _tweenFrame:Number;
    public function set tweenFrame(value:Number):void{
      _tweenFrame = value;
      gotoAndStop(int(value));
    }
    public function get tweenFrame():Number{
      return _tweenFrame;
    }
  }
}

//...
var tm:TweenableMC=new TweenableMC(myMc);
tm.playFromTo(50, 75, 1); // play from 50 to 75 in 1 second