Question

My form contains several NumericUpDown controls. These controls show different amount of decimal places.
Later in my code I put the different NumericUpDown.Value‘s in a string array arrStr() like so:

arrStr(1) = NumericUpDown1.Value
arrStr(2) = NumericUpDown2.Value
arrStr(3) = NumericUpDown3.Value

Then I print the array with the File.WriteAllLines function to a text file.
If for example NumericUpDown1.Value = 1.00, NumericUpDown2.Value = 2.30 and NumericUpDown3.Value = 2.124 the file has the following values in it:

1
2.3
2.124

I would like to see:

1.00
2.30
2.124

I have tried Format which works, but that formatting method is not convenient as the amount of decimal places is already set for each NumericUpDown. It would be annoying to do the work again, but now with Format.

Answer 1

You could use String.Format to force two decimal places:

Dim value As Double = 2.3
Dim formatted = String.Format("{0:f2}", value) ' 2.30 '

Standard Numeric Format Strings

Edit: If you’re array is large and you want to avoid:

arrStr(1) = String.Format("{0:f2}", NumericUpDown1.Value) up to arrStr(86) = String.Format("{0:f2}", NumericUpDown86.Value)

You can use LINQ to create the array. Assuming that your NumericUpDown controls are all in a GroupBox called NumericGroupBox. You can “inject” the correct number of decimal places:

Dim arrStr() As String =
        (From n In NumericGroupBox.Controls.OfType(Of NumericUpDown)()
        Select String.Format("{0:f" & n.DecimalPlaces & "}", n.Value)).ToArray()

and here’s a version that searches all TabPages of your TabControl(as commented):

Dim allNumerics = From tp In Me.TabControl1.TabPages.Cast(Of TabPage)()
                  From n In tp.Controls.OfType(Of NumericUpDown)()
                  Select String.Format("{0:f" & n.DecimalPlaces & "}", n.Value)
Dim arrStr As String() = allNumerics.ToArray()