Question

My minecraft server tends to crash fairly often so I wrote a script that checks my minecraft server, if its up it does nothing, if it is down it executes this code:

Set oShell= CreateObject("WScript.Shell") 
strProcess = "cmd.exe" 
oShell.Run "TaskKill /im " & strProcess & " /f /t", , True
WScript.sleep 1000
oShell.Run "c:\minecraft_launch.bat"
Set oShell = Nothing 

Basically I kill any currently running server (cmd since it is being run from a batch file) then I start it back up. This check is run every 5mins via task scheduler.

This is the contents of the batch file:

@echo off
"C:\Program Files\Java\jre6\bin\java.exe" -Xmx1024M -Xms1024M -jar "%appdata%\- minecraft_server\minecraft_server.jar" >> "%appdata%\- minecraft_server\s.log"

When I run it, it works. Everytime, but…..When it runs automatically, it stops working. I don’t know how many times it will work until it quits. What happens is I notice it is down, so I check my computer. No server running, no process running, no javaw.exe or cmd.exe running. Nothing, but when I try to start the server it won’t start. I have to reboot the whole machine to get the server to start. I think I am missing something stupid simple here. Any ideas?

Answer 1

The problem could be that the timeout is too short so you try to start it while it’s still being closed. In any way, vbscript itself can check and terminate processes with more controll. See http://www.activexperts.com/activmonitor/windowsmanagement/adminscripts/processes/ for short scripts that monitor and stop processes.
Here a script from Rob Van der woude which usually are reliable, this monitors outlook.exe so i guess you would be monitoring javaw.exe

KillProc "outlook.exe"

Sub KillProc( myProcess )
'Authors: Denis St-Pierre and Rob van der Woude
'Purpose: Kills a process and waits until it is truly dead

    Dim blnRunning, colProcesses, objProcess
    blnRunning = False

    Set colProcesses = GetObject( _
                       "winmgmts:{impersonationLevel=impersonate}" _
                       ).ExecQuery( "Select * From Win32_Process", , 48 )
    For Each objProcess in colProcesses
        If LCase( myProcess ) = LCase( objProcess.Name ) Then
            ' Confirm that the process was actually running
            blnRunning = True
            ' Get exact case for the actual process name
            myProcess  = objProcess.Name
            ' Kill all instances of the process
            objProcess.Terminate()
        End If
    Next

    If blnRunning Then
        ' Wait and make sure the process is terminated.
        ' Routine written by Denis St-Pierre.
        Do Until Not blnRunning
            Set colProcesses = GetObject( _
                               "winmgmts:{impersonationLevel=impersonate}" _
                               ).ExecQuery( "Select * From Win32_Process Where Name = '" _
                             & myProcess & "'" )
            WScript.Sleep 100 'Wait for 100 MilliSeconds
            If colProcesses.Count = 0 Then 'If no more processes are running, exit loop
                blnRunning = False
            End If
        Loop
        ' Display a message
        WScript.Echo myProcess & " was terminated"
    Else
        WScript.Echo "Process """ & myProcess & """ not found"
    End If
End Sub