Question

My problem can be illustrated in the following example code, which sets up a data array of friends, each of which can have several phone numbers:

Class clsPhoneNo
  Dim strType
  Dim strNumber
End Class

Class clsPerson
  Dim strName
  Dim aclsPhoneNo()
End Class

Dim clsFriends()
ReDim clsFriends(3)
Set clsFriend(0) = New Person
clsFriend(0).strName = "Fred"
Set clsFriends(0).aclsPhoneNo(0) = New clsPhoneNo
ReDim clsFriend(0).aclsPhoneNo(2)
Set clsFriend(0).aclsPhoneNo(0).strType = "Home"
Set clsFriend(0).aclsPhoneNo(0) = "01234567890"
Set clsFriend(0).aclsPhoneNo(1).strType = "Work"
Set clsFriend(0).aclsPhoneNo(1) = "09876543210"

However, VBScript says

Microsoft VBScript compilation error: Expected end of statement

Before the . on the second ReDim statement

I need to have the aclsPhoneNo element variable length as my code isn’t really an address book, but this is a simple example demonstrating the issue.

Any ideas?

Answer 1

Arrays are the wrong data structure to solve this problem. They are the weapon of choice in other languages, they are not in VBScript, for they are notoriously inflexible.

Consider using Dictionaries instead. And drop the Hungarian.

Dim phoneBook: Set phoneBook = New ObjectList

With phoneBook.Append(New Person)
  .Name = "fred"
  .AddPhoneNo "Home", "01234567890"
  .AddPhoneNo "Work", "09876543210"
End with

Dim pers: Set pers = phoneBook.Item(1)

For Each id In pers.PhoneNos.List
  Set num = pers.PhoneNos.List(id)
  WScript.Echo pers.Name & " #" & id & ": " & _
               num.Number & " (" & num.Label & ")"
Next

' ------------------------------------------------------
Class ObjectList
  Public List

  Sub Class_Initialize()
    Set List = CreateObject("Scripting.Dictionary")
  End Sub

  Sub Class_Terminate()
    Set List = Nothing
  End Sub

  Function Append(Anything) 
    List.Add CStr(List.Count + 1), Anything 
    Set Append = Anything
  End Function

  Function Item(id) 
    If List.Exists(CStr(id)) Then
      Set Item = List(CStr(id))
    Else
      Set Item = Nothing
    End If
  End Function
End Class

' ------------------------------------------------------
Class PhoneNo
  Public Label
  Public Number
End Class

' ------------------------------------------------------
Class Person
  Public Name
  Public PhoneNos

  Sub Class_Initialize()
    Set PhoneNos = New ObjectList
  End Sub

  Function AddPhoneNo(Label, Number)
    Set AddPhoneNo = New PhoneNo
    With PhoneNos.Append(AddPhoneNo)
      .Label  = Label
      .Number = Number
    End With
  End Function
End Class 

Note that I made use of a few VB features here

• You can use functions and classes before they are defined in the script, so put all your plumbing at the bottom.
• You can have Public and Private class variables
• Classes have an Initiate and a Terminate event that you can react to
• Function names are variable declarations. No need to declare a temporary return variable in a function, you can use the function name for that.
• The With block can save you a temporary variable as well.
• Even though the dictionary is comparatively convenient, it can still benefit from convenience wrapper, so I created one.