Question

My problem is that I am not able to figure out that why my code is taking each of the line from the file as one element of an array instead of taking the whole record starting from AD to SS as one element of the array. As you can see that my file is starting from AD and ending at SS which is same for all the followed lines in the data. But I want to make the array having elements starting from AD to SS which will be having all the lines in between AD to SS that is BC….,EG…., FA…..etc.not each line as an element. I tried my way and get the same file as such.Could anyone check my code. Thanks in advance.

AD uuu23

BC jjj

EG iii

FA vvv

SS

AD hhh25

BC kkk

EG ppp

FA aaa

SS

AD ttt26

BC xxx

FA rrr

SS

#!/usr/bin/env perl
 use strict;
 use warnings;

 my $ifh;
 my $line = '';
 my @data;

 my $ifn  = "fac.txt";

 open ($ifh, "<$ifn") || die "can't open $ifn";
 my $a = "AD  "; 
 my $b = "SS ";
 my $_ = " ";
 while ($line = <$ifh>)
 {
 chomp 
 if ($line =~ m/$a/g); {
  $line = $_;

  push @data, $line;

 while ($line = <$ifh>) 
{
$line .= $_;

push @data, $line;

last if 
($line =~ m/$b/g);
}

}
push @data, $line; }


print @data;

Answer 1

Here’s a way to accomplish reading the records into an array, with newlines removed:

Code:

use strict;
use warnings;
use autodie;

my @data;
my $record;
my $file = "fac.txt";
open my $fh, '<', $file;

while (<$fh>) {
    chomp;
    if (/^AD /) { # new record starts
        $record = $_;
        while (<$fh>) {
            chomp;
            $record .= $_;
            last if /^SS\s*/;
        }
        push @data, $record;
    } else { die "Data outside record: $_" }
}

use Data::Dumper;
print Dumper \@data;

Output:

$VAR1 = [
          'AD uuu23BC jjjEG iiiFA vvvSS',
          'AD hhh25BC kkkEG pppFA aaaSS',
          'AD ttt26BC xxxFA rrrSS'
        ];

This is another version, using the input record separator $/:

use strict;
use warnings;
use autodie;

my $file = "fac.txt";
open my $fh, '<', $file;

my @data;
$/ = "\nSS";
while (<$fh>) {
    s/\n//g;
    push @data, $_;
}

use Data::Dumper;
print Dumper \@data;

Produces the same output with this data. It does not care about the record start characters, only the end, which is SS at the beginning of a line.