Question

My script needs to get a series of numbers input by the user and find the average of them. I would like to use the line ‘end-of-file’ to show that the user is done inputting code. Any help would be appreciated. Below is what I have so far. I think I am really close, but I am missing something.

Code:

#! /usr/bin/perl
use 5.010;


print "Enter the scores and type end-of-file when done";
chomp(@scores = <STDIN>);
foreach (@scores) {
    push_average(total(@scores));
}




sub total {
    my $sum;
    foreach (@_) {
        $sum += $_;
    }
    sum;
}

sub average {
    if (@_ == 0) {return}
    my $count = @_;
    my $sum = total(@_);
    $sum/$count;
}

sub push_average {
    my $average = average(@_);
    my @list;
    push @list, $average;
    return @list;
}

Answer 1

You are quite close. Adding use strict; use warnings at the top of every Perl script will alert you of errors that might go unnoticed otherwise.

A few hints:

• You forgot the sigil of $sum in the last statement of total. Currently, you return a string “sum” (without strict vars), or possibly call a sub called sum.

• You don’t need the foreach in the main part, rather do

  my @averages = push_average(@scores);
  

  The total is already calculated inside push_average

• You probably want to print out the resulting average:

  my $avg = $averages[0];
  say "The average of these numbers is $avg";
  

• The push_average is silly; you return a new array of one element. You could return that one element just as well.

---

Suggested script:

use strict; use warnings; use 5.010;
use List::Util qw/sum/;  # very useful module

# say is like print, but appends a newline. Available with 5.10+
say "Please enter your numbers, finish with Ctrl+D";
my @nums = <STDIN>;
chomp @nums;

# The // is the defined-or operator
# interpolating undef into a string causes a warning.
# Instead, we give an expressive message:
my $avg = average(@nums) // "undefined"; 

say "The average was $avg";

sub average { @_ ? sum(@_) / @_  : undef } # return undef value if called without args