Question

My worksheet is basically a metrics worksheet that has multiple columns that rely on a date entered into one column, but each of these later columns then rely on each other in sequence for setting dates and time periods.

I’m trying to find a way to update certain columns within the same row when that first value is changed; through the Worksheet_SelectionChange event if possible (or some other way if the result is the same).

What I want to happen: I enter a “start” date in column A. I need excel to then update column B of the same row based on the value in column A. Then I need column C (same row) to update based on the new value in column B; then I need column D to update based on the value in column C; and so on. Does this make sense?

Answer 1

You seem to really want VBA, so I’ll post another answer (quite different from my other one).

Here I use the Worksheet_Change event. It calls a function that returns an array of type Variant containing dates. This array can then be written to the sheet simply using =.

I find this slightly more complicated than just using formulas in cells, but it has the advantage of a cleaner front-end, which you seem to want.

In the sheet module:

Private Sub Worksheet_Change(ByVal Target As Range)

    If Not Intersect(Target, Range("A:A")) Is Nothing Then
        Target.Offset(0, 1).Resize(1, 3) = RelevantDates(Target.Value)
    End If

End Sub

In a code module:

Function RelevantDates(startDate As Date) As Variant
    Dim v As Variant
    ' Adapt to your needs:
    ReDim v(1 To 3)
    v(1) = startDate + 1 ' add one day
    v(2) = DateSerial(Year(v(1)), Month(v(1)), Day(v(1)) + 7) ' add one more week
    v(3) = DateSerial(Year(v(2)), Month(v(2)) + 1, Day(v(2))) ' add one month
    RelevantDates = v
End Function

Of course the above only returns 3 rather trivial dates, but you can customise this as you see fit.